Check which entry has character length 8

[learning_bee]

Hi I want to get marks obtained for the student whose name has 8 characters... How can I do that?

[AliGW]

Welcome to the forum.

There are instructions at the top of the page explaining how to attach your sample workbook.

A good sample workbook has just 10-20 rows of representative data that has been desensitised. It also has expected results mocked up, worked examples where required, relevant cells highlighted and a few explanatory notes.

[Glenn Kennedy]

You cna use:

=INDEX(B$2:B$10,MATCH(1,INDEX(--(LEN($A$2:$A$10)=8),0),0))

copied across. See file & adapt the ranges to suit...

Can there be more than 1 with a string length of 8? if so, what do you want to happpen?

[learning_bee]

It worked .. Thank you so much, I was stuck in this problem from last week. But I did not understand one thing why did you put two dashes before length function?
Also no there cannot be more than one cell with length 8 .. but can you tell me what can we use if we get more than one cell with same length ?

[learning_bee]

Thank you so much....I am new here so i didn't know about this but I will keep that in mind from now on...

[Glenn Kennedy]

yES.

=IFERROR(INDEX(B:B,AGGREGATE(15,6,ROW($A$2:$A$10)/(LEN($A$2:$A$10)=8),ROWS(H$2:H2))),"")

copied across and down.


You're welcome.

---

It would be very nice if you were to just click the Add Reputation button at the foot of any of the posts of members who helped you reach a solution.

Finally, if that takes care of your original question, please select "Thread Tools" from the menu link (just above the first post in the thread) and mark this thread as SOLVED.

[learning_bee]

But I did not understand one thing why did you put two dashes before length function in the first solution?

[Glenn Kennedy]

=INDEX(B$2:B$10,MATCH(1,INDEX(--(LEN($A$2:$A$10)=8),0),0))

LEN($A$2:$A$10)=8

returns as series of TRUE or FALSE results. the -- converts those into 1 and 0... MATCH is looking for the first 1 it sees.

It could, equally, have been written as:

=INDEX(B$2:B$10,MATCH(TRUE,INDEX(LEN($A$2:$A$10)=8,0),0))

[learning_bee]

Got it...Thank you sir...