Timer that starts counting up in mins soon as a cell is filled

I want a time tracker that will count time soon as a specific cell is filled.
Example:
a column has a drop down list of items, b column start counting minutes soon as the item is chosen from the dropdown list. soon as column c is filled the counter stops.

Have a try with these macros.

To be pasted in a standard module:

Option Explicit
Public On_Off  As Boolean
Public Tempo   As Double
Public rowTarget As Range

Sub Clock()
    DoEvents
    If On_Off = True Then Exit Sub
    Application.EnableEvents = False
    rowTarget.Offset(0, 1).Value = Format(Now - Tempo, "hh:mm:ss")
    Application.EnableEvents = True
    Application.OnTime Now + TimeSerial(0, 0, 1), "Clock"
End Sub

Sub S_tart()
    On_Off = False
    Tempo = Now
    Call Clock
End Sub

Sub S_top()
    On_Off = True
End Sub

To be pasted in the Sheet1's module:

Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Row < 4 Then Exit Sub
    Select Case Target.Column
        Case Is = 2
            Set rowTarget = Target
            Target.Offset(0, 2).Select
            Call S_tart
        Case Is = 4
            Call S_top
    End Select
End Sub