Form Menu : Check Box

[jagstirling]

I am trying to enter 300 or so check boxes onto and Excel spreadsheet.

I find that I can link the 'return' cell using the right click / Format Control / Control tab / Cell Link option but I need to do this for each box !

Is there a way around this ? Whereby I can create one Check Box and then drag or copy it down ?

[Dave Peterson]

Maybe you could just use a macro to populate the range you want.


Option Explicit
Sub addCBX()
Dim myCBX As CheckBox
Dim myCell As Range

With ActiveSheet
.CheckBoxes.Delete 'nice for testing
For Each myCell In ActiveSheet.Range("a1:a50").Cells
With myCell
Set myCBX = .Parent.CheckBoxes.Add _
(Top:=.Top, Width:=.Width, _
Left:=.Left, Height:=.Height)
With myCBX
.LinkedCell = myCell.Address(external:=True)
.Caption = "" 'or whatever you want
.Name = "CBX_" & myCell.Address(0, 0)
End With
.NumberFormat = ";;;"
End With
Next myCell
End With
End Sub

If you're new to macros, you may want to read David McRitchie's intro at:
http://www.mvps.org/dmcritchie/excel/getstarted.htm

jagstirling wrote:
>
> I am trying to enter 300 or so check boxes onto and Excel spreadsheet.
>
> I find that I can link the 'return' cell using the right click / Format
> Control / Control tab / Cell Link option but I need to do this for each
> box !
>
> Is there a way around this ? Whereby I can create one Check Box and
> then drag or copy it down ?
>
> --
> jagstirling
> ------------------------------------------------------------------------
> jagstirling's Profile: http://www.excelforum.com/member.php...fo&userid=1100
> View this thread: http://www.excelforum.com/showthread...hreadid=506342

--

Dave Peterson

[jagstirling]

Many thanks Dave