Insert pictures

**richard11153** · 11-25-2010, 12:30 PM

I am using excel 2003 on windows 7
When I go to insert a "picture from file", the thumbnails are so small
I can hardly see what each pitcure is.
Is there a way to make thumbnails bigger by defalt?
If anyone has an answer or can suggest any other way to insert pictures
from a list / file, that I can actually see, please let me know.
I insert about 30 or so pictures in each report.

Thanks / RS

**davesexcel** · 11-26-2010, 08:06 AM

Dave Peterson gave me this code years ago in groups forum, you can select a range then run the code, when you have selected your picture from the file, it will insert the picture into your selection

Option Explicit
Private Declare Function SetCurrentDirectoryA Lib _
                                              "kernel32" (ByVal lpPathName As String) As Long
Sub ChDirNet(szPath As String)
    Dim lReturn As Long
    lReturn = SetCurrentDirectoryA(szPath)
    If lReturn = 0 Then Err.Raise vbObjectError + 1, "Error setting path."
End Sub
Sub testme01()

    Dim myPictureName As Variant
    Dim myPict As Picture
    Dim myRng As Range
    Dim myCurFolder As String
    Dim myNewFolder As String

    myCurFolder = CurDir
    myNewFolder = "yourfoldernamehere"

    On Error Resume Next
    ChDirNet myNewFolder
    If Err.Number <> 0 Then
        'what should happen
        MsgBox "Please change to your own folder"
        Err.Clear
    End If
    On Error GoTo 0

    myPictureName = Application.GetOpenFilename(filefilter:="PictureFiles,*.jpg;*.bmp;*.tif;*.gif")

    ChDirNet myCurFolder

    If myPictureName = False Then
        Exit Sub    'user hit cancel
    End If

    Set myRng = Selection.Areas(1)
    Set myPict = myRng.Parent.Pictures.Insert(myPictureName)
    myPict.Top = myRng.Top
    myPict.Width = myRng.Width
    myPict.Height = myRng.Height
    myPict.Left = myRng.Left
    myPict.Placement = xlMoveAndSize

End Sub