+ Reply to Thread
Results 1 to 11 of 11

Show =SUMIF data within other file without opening it?

  1. #1
    Forum Contributor
    Join Date
    02-13-2012
    Location
    UK
    MS-Off Ver
    Excel 2013
    Posts
    105

    Show =SUMIF data within other file without opening it?

    Hi,

    I have a =SUMIF & =IF formula written within a sheet. They both point towards another spreadsheet to harvest data and I have noticed that the data is fetched automatically within the =IF formula (without the other sheet open) but the =SUMIF formula only displays the data when I open the other sheet.

    Is there a way I can get the =SUMIF cell to update with the need to open up the file each time?


    =IF($A11="","",IF(ISNA(MATCH($A11&"_"&COLUMN(A$5),'\\ORBITALHUB\Employees\Greg Tudor\Greg Folder\[Test.xlsx]Sheet1'!$M:$M,0)),"",INDEX('\\ORBITALHUB\Employees\Greg Tudor\Greg Folder\[Test.xlsx]Sheet1'!$J:$J,MATCH($A11&"_"&COLUMN(A$5),'\\ORBITALHUB\Employees\Greg Tudor\Greg Folder\[Test.xlsx]Sheet1'!$M:$M,0))))


    =SUMIF('\\ORBITALHUB\Employees\Greg Tudor\Greg Folder\[Test.xlsx]Sheet1'!$C$2:$C$101786,A11,'\\ORBITALHUB\Employees\Greg Tudor\Greg Folder\[Test.xlsx]Sheet1'!$F$2:$F$101786)
    Last edited by NBVC; 02-24-2012 at 08:54 AM.

  2. #2
    Forum Expert
    Join Date
    03-23-2004
    Location
    London, England
    MS-Off Ver
    Excel 2019
    Posts
    7,062

    Re: Show =SUMIF data within other file without opening it?

    http://support.microsoft.com/kb/260415
    Regards
    Special-K

    Ensure you describe your problem clearly, I have little time available to solve these problems and do not appreciate numerous changes to them.

  3. #3
    Forum Contributor
    Join Date
    02-13-2012
    Location
    UK
    MS-Off Ver
    Excel 2013
    Posts
    105

    Re: Show =SUMIF data within other file without opening it?

    Thanks for that. Can't seem to get it to work though.

  4. #4
    Forum Expert NBVC's Avatar
    Join Date
    12-06-2006
    Location
    Mississauga, CANADA
    MS-Off Ver
    2003:2010
    Posts
    34,898

    Re: Show =SUMIF data within other file without opening it?

    SUMIF doesn't work with closed workbooks, the alternative is to use SUMPRODUCT

    e.g.

    =SUMPRODUCT(--('\\ORBITALHUB\Employees\Greg Tudor\Greg Folder\[Test.xlsx]Sheet1'!$C$2:$C$101786=A11),'\\ORBITALHUB\Employees\Greg Tudor\Greg Folder\[Test.xlsx]Sheet1'!$F$2:$F$101786)
    Where there is a will there are many ways.

    If you are happy with the results, please add to the contributor's reputation by clicking the reputation icon (star icon) below left corner

    Please also mark the thread as Solved once it is solved. Check the FAQ's to see how.

  5. #5
    Forum Contributor
    Join Date
    02-13-2012
    Location
    UK
    MS-Off Ver
    Excel 2013
    Posts
    105

    Re: Show =SUMIF data within other file without opening it?

    Still no luck with =SUMPRODUCT

  6. #6
    Forum Expert NBVC's Avatar
    Join Date
    12-06-2006
    Location
    Mississauga, CANADA
    MS-Off Ver
    2003:2010
    Posts
    34,898

    Re: Show =SUMIF data within other file without opening it?

    Try creating the SUMPRODUCT first with the other workbook open...

    =SUMPRODUCT(--('[Test.xlsx]Sheet1'!$C$2:$C$101786=A11),'[Test.xlsx]Sheet1'!$F$2:$F$101786)

    then, if it works, close the other workbook.. and recalculate.

  7. #7
    Forum Contributor
    Join Date
    02-13-2012
    Location
    UK
    MS-Off Ver
    Excel 2013
    Posts
    105

    Re: Show =SUMIF data within other file without opening it?

    Still no joy. The forumla is sort of working as it just returns a value of '0' and not an #VALUE! error. I just cannot get it to work out.

  8. #8
    Forum Expert
    Join Date
    12-23-2006
    Location
    germany
    MS-Off Ver
    XL2003 / 2007 / 2010
    Posts
    6,326

    Re: Show =SUMIF data within other file without opening it?

    Maybe post a small sample of your sheets were the problem occurs

  9. #9
    Forum Contributor
    Join Date
    02-13-2012
    Location
    UK
    MS-Off Ver
    Excel 2013
    Posts
    105

    Re: Show =SUMIF data within other file without opening it?

    Sample sheets attached (red column with =sumif & =sumproduct formula). Thanks in advance for your help.
    Attached Files Attached Files

  10. #10
    Forum Expert daddylonglegs's Avatar
    Join Date
    01-14-2006
    Location
    England
    MS-Off Ver
    2016
    Posts
    14,675

    Re: Show =SUMIF data within other file without opening it?

    Looks like a mismatch between a numeric value and a text value (SUMIF can handle that but SUMPRODUCT doesn't), try making A11 text by concatenating with ""in the formula, i.e. open both files and then use this formula in G11 copied down

    =IF(A11="",0,SUMPRODUCT(--([Test.xlsx]Sheet1!$C$2:$C$101792=A11&""),[Test.xlsx]Sheet1!$F$2:$F$101792))

    Now you can close test file
    Audere est facere

  11. #11
    Forum Contributor
    Join Date
    02-13-2012
    Location
    UK
    MS-Off Ver
    Excel 2013
    Posts
    105

    Re: Show =SUMIF data within other file without opening it?

    Brilliant. Thanks very much.

+ Reply to Thread

Thread Information

Users Browsing this Thread

There are currently 1 users browsing this thread. (0 members and 1 guests)

Bookmarks

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts

Search Engine Friendly URLs by vBSEO 3.6.0 RC 1