Excel 2008 : Excel 2010 Export or copy values from chart

[kwrom]

I have downloaded a file containing a chart made from values from another excel file (which I don't have access to). Is there a way for me to export or copy these values into a table in excel?

I'm attaching the file with the chart, in case someone needs to see it to understand what I'm talking about.

chart.xls

[Andy Pope]

You can with vba

Sub ExtractValues()

    Dim objSeries As Series
    Dim lngRow As Long
    Dim lngCol As Long
    Dim chtTemp As Chart
    Dim vntItem As Variant
    
    Set chtTemp = ActiveSheet.ChartObjects(1).Chart
    lngCol = 1
    For Each objSeries In chtTemp.SeriesCollection
        lngRow = 24
        If lngCol = 1 Then
            lngRow = lngRow + 1
            For Each vntItem In objSeries.XValues
                Cells(lngRow, lngCol) = vntItem
                lngRow = lngRow + 1
            Next
        Else
            Cells(lngRow, lngCol) = objSeries.Name
            lngRow = lngRow + 1
            For Each vntItem In objSeries.Values
                Cells(lngRow, lngCol) = vntItem
                lngRow = lngRow + 1
            Next
        End If
        lngCol = lngCol + 1
    Next
    
End Sub

[kwrom]

Yey, it worked! No way Google could have helped me with that one. Thanks a lot for your help, you are a lifesaver!