Resolve output based on numbers in a cell

**pipersbytes** · 08-17-2015, 12:14 PM

Cell C3 is a Number, selected from a drop down menu.

Basically, if this cell is specific numbers, I need cell C15 to reflect this based on the below.

Is there a variation of the IF statement that I can use in cell C15 to reflect this?

If C3=1 OR 2, fill in C15 with the number 2
If C3=3 OR 4, fill in C15 with the number 4
If C3=5 OR 6, fill in C15 with the number 6
If C3=7 OR 8, fill in C15 with the number 8
If C3=9 OR 10, fill in C15 with the number 10
If C3=11 OR 12, fill in C15 with the number 12
If C3=13 OR 14, fill in C15 with the number 14
If C3=15 OR 16, fill in C15 with the number 16

Thanks.

**Jdevil** · 08-17-2015, 12:46 PM

Two ways:

First, the easiest would be a nested if: (In C15)

=IF(C3<3,2,IF(C3<5,4,IF(C3<7,6,IF(C3<9,8,IF(C3<11,10,IF(C3<13,12,IF(C3<15,14,16)))))))

That would work too:

(EDIT: Forget it, made a mistake, here's the working one: )

=IF(ROUND(C3/2,0)=C3/2,C3,C3+1)

**Pepe Le Mokko** · 08-17-2015, 12:48 PM

Try =CEILING(C3,2)

**Jdevil** · 08-17-2015, 01:16 PM

Originally Posted by Pepe Le Mokko

Try =CEILING(C3,2)

Did not know that was a thing. Neat!

**ChemistB** · 08-17-2015, 03:28 PM

or

=MROUND(C2,2)

**ChemistB** · 08-17-2015, 03:32 PM

Or
=INT((C2+1)/2)*2

or
=TRUNC((C2+1)/2)*2

**ChemistB** · 08-17-2015, 03:37 PM

Orrrrrrrrr

=CHOOSE(C2,2,2,4,4,6,6,8,8,10,10)

**ChemistB** · 08-17-2015, 03:39 PM

Maybe

=LOOKUP(C2, {1,3,5,7,9}, {2,4,6,8,10})

**ChemistB** · 08-17-2015, 04:51 PM

Or if you want to impress

=INDEX(ROW($A$1:$A$6)*2, INT((C2+1)/2))

No one else wants to play?

**pipersbytes** · 08-17-2015, 05:17 PM

Thank you guys!

**pipersbytes** · 08-17-2015, 05:36 PM

Newbie to forum question: how do I mark the thread as resolved?

**ChemistB** · 08-18-2015, 08:48 AM

Go to your first post and on the middle right is "Thread Tools dropdown. Should be "Mark as Solved" in there.

Resolve output based on numbers in a cell

LinkBack

Thread Tools

Rate This Thread

Display

Resolve output based on numbers in a cell

Re: Resolve output based on numbers in a cell

Re: Resolve output based on numbers in a cell

Re: Resolve output based on numbers in a cell

Re: Resolve output based on numbers in a cell

Re: Resolve output based on numbers in a cell

Re: Resolve output based on numbers in a cell

Re: Resolve output based on numbers in a cell

Re: Resolve output based on numbers in a cell

Re: Resolve output based on numbers in a cell

Re: Resolve output based on numbers in a cell

Re: Resolve output based on numbers in a cell

Thread Information

Users Browsing this Thread

Similar Threads

[SOLVED] Output a specific number from range of numbers in one cell

Search cell text and output different values based on result in another cell

can any body plz help me to resolve my employee allocation list. (based on the place name

Output specific Cell Value based on last occurance of a Value in far left cell.

Variable Output Based on Another Cell

VBA Output based on what's typed into Cell.

Output list based on value in a cell

Bookmarks

Bookmarks

Posting Permissions