Modify Code to Tab/Space Delimit (Instead of "|")

Hello All -

I was able to find this code online, which works perfect for grabbing .txt files from a folder location and producing .xlsx files into an output folder. However; I am looking to delimit the .txt files by TAB & SPACE (not "|"). Can someone show me what I'd need to do to modify this code?

Any help is MUCH appreciated.

Sub tgr()    
    Const txtFldrPath As String = "C:\TextFiles"      'Change to folder path containing text files
    Const xlsFldrPath As String = "C:\ExcelOutput"     'Change to folder path excel files will be saved to
    
    Dim CurrentFile As String: CurrentFile = Dir(txtFldrPath & "\" & "*.txt")
    Dim strLine() As String
    Dim LineIndex As Long
    
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
    While CurrentFile <> vbNullString
        LineIndex = 0
        Close #1
        Open txtFldrPath & "\" & CurrentFile For Input As #1
        While Not EOF(1)
            LineIndex = LineIndex + 1
            ReDim Preserve strLine(1 To LineIndex)
            Line Input #1, strLine(LineIndex)
        Wend
        Close #1
        
        With ActiveSheet.Range("A1").Resize(LineIndex, 1)
            .Value = WorksheetFunction.Transpose(strLine)
            .TextToColumns Other:=True, OtherChar:="|"
        End With
        
        ActiveSheet.UsedRange.EntireColumn.AutoFit
        ActiveSheet.Copy
        ActiveWorkbook.SaveAs xlsFldrPath & "\" & Replace(CurrentFile, ".txt", ".xls"), xlNormal
        ActiveWorkbook.Close False
        ActiveSheet.UsedRange.ClearContents
        
        CurrentFile = Dir
    Wend
    Application.DisplayAlerts = True
    Application.ScreenUpdating = True    
End Sub

.TextToColumns DataType:=xlDelimited, Tab:=True, Space:=True, Other:=False

replaces

.TextToColumns Other:=True, OtherChar:="|"