Hide/show columns if checkbox (UserForm) is TRUE

Hi everybody,

I'm newcomer into the field of VBA programming and I'm currently trying to figure out this task (for most of you probably easy to solve):

1. load UserForm with 12 checkboxes when one can check criteria he wants
2. macro should then, based on the user's option, hide/show all relevant columns containing detailed information.

Private Sub CommandButton1_Click()

       For x = 1 To 12

        CheckboxX = "CheckBox" & x

            y = 6 + x

            ActiveWorkbook.Worksheets("Zamėstnanec 1").Activate

            If CheckboxX = True Then

                Columns(y).EntireColumn.Hidden = False

            Else

                Columns(y).EntireColumn.Hidden = True

            End If

        Next


   Unload UserForm1

End Sub

When I run the macro, it works without breaking down, but it always hide all of the columns. Could you please help me out with it?

Thank you so much for help!

Can you upload your workbook?

You werent actually checking the value of the checkboxes, the following line:

CheckboxX = "CheckBox" & x

simply created a variable and populated it with "Checkbox1", "Checkbox2" etc which never equals True.

You need to cycle through the controls in the form and action accordingly.

Private Sub CommandButton1_Click()
Dim cCont As Control
    For Each cCont In Me.Controls 'cycle through all elements on the form allocating each in turn to the object "cCont"
        If (Left(cCont.Name, 5) = "Check") Then 'check if name of object begins with "Check", if so its a checkbox
            y = Int(Right(cCont.Name, Len(cCont.Name) - 8)) + 6 'strip off the word "Checkbox" to leave the number
                If (cCont.Value = True) Then ' check if its value is True
                    Columns(y).EntireColumn.Hidden = False
                Else
                    Columns(y).EntireColumn.Hidden = True
                End If
        End If
    Next cCont
Unload UserForm1
End Sub