Current Code not working

[zplugger]

Have to code but getting problem if more then one character is in C13. Works perfect if only one character is typed in cell,how can I change
it so if more then one invalid character is in cell? Thanks for any suggestions. Z
For example this get error 45 elm. 4/23/2015

Private Sub Worksheet_Change(ByVal Target As Range)
Dim str, i As Long
    
    str = Array(".", "/", "\")

    With Range("C13")
        For i = LBound(str) To UBound(str)
            If InStr(1, .Value, str(i)) > 0 Then

            jobbox1.Show
              
                End If
        Next i
    End With
End Sub

This is the code on userform yes button

Private Sub CommandButton1_Click()
Dim str, i As Long

     'List of characters
    str = Array(".", "/", "\")

    With Range("C13")
        For i = LBound(str) To UBound(str)
            If InStr(1, .Value, str(i)) > 0 Then
                
                    .Value = Replace(.Value, str(i), "")
                End If
            
        Next i
    End With
     Unload Me
     
    Range("C13").Select
    
End Sub

[buran]

There is no need to check with InStr. Just loop trough invalid chars and use the replace. If the char is not found nothing will happen.

Private Sub CommandButton1_Click()
Dim str, i As Long

     'List of characters
    str = Array(".", "/", "\")

    With Range("C13")
        For i = LBound(str) To UBound(str)
                    .Value = Replace(.Value, str(i), "")
        Next i
    End With
    Unload Me  
End Sub

[zplugger]

Thanks buran
Getting error still? This only happens if more then one character is inputed.
Form already displayed;can't show modally

[buran]

Oh, I misunderstood your problem. Sorry

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim str As Variant
    Dim i As Long
    Dim bInvalidChar As Boolean

    If Not Intersect(Target, Range("C13")) Is Nothing Then    'This will prevent rest of the code run if C13 has not changed
        str = Array(".", "/", "\")
        With Range("C13")
            bInvalidChar = False
            For i = LBound(str) To UBound(str)
                If InStr(1, .Value, str(i)) > 0 Then
                    bInvalidChar = True
                End If
            Next i
        End With
        If bInvalidChar Then    'Invalid Char Found
            jobbox1.Show
        End If
    End If
End Sub

Private Sub CommandButton1_Click()
    Dim str As Variant
    Dim i As Long
    'List of characters
    str = Array(".", "/", "\")

    With Range("C13")
        For i = LBound(str) To UBound(str)
            .Value = Replace(.Value, str(i), "")
        Next i
    End With
    Unload Me
End Sub

[zplugger]

Thanks buran, seems to be working now.