Combine mail VBA, and make it insert a timestamp.

I have this VBA for a "send mail button"

-Is there a way to make this leave a timestamp in "A10" that says "Shipped TIME+DATE" ?

Sub MailAugust()
    Dim Source As Range
    Dim Dest As Workbook
    Dim wb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim OutApp As Object
    Dim OutMail As Object

    Set Source = Nothing
    On Error Resume Next
    Set Source = Range("AX1:CT43").SpecialCells(xlCellTypeVisible)
    On Error GoTo 0

    If Source Is Nothing Then
        MsgBox "The source is not a range or the sheet is protected, please correct and try again.", vbOKOnly
        Exit Sub
    End If

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set wb = ActiveWorkbook
    Set Dest = Workbooks.Add(xlWBATWorksheet)

    Source.Copy
    With Dest.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial Paste:=xlPasteValues
        .Cells(1).PasteSpecial Paste:=xlPasteFormats
        .Cells(1).Select
        Application.CutCopyMode = False
    End With

    TempFilePath = Environ$("temp") & "\"
    TempFileName = "pay" & " " & Format(Now, "dd-mmm-yy")

    If Val(Application.Version) < 12 Then
       
        FileExtStr = ".xls": FileFormatNum = -4143
    Else
       
        FileExtStr = ".xlsx": FileFormatNum = 51
    End If

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    With Dest
        .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum
        On Error Resume Next
        With OutMail
            .To = ""
            .CC = ""
            .BCC = ""
            .Subject = "Pay"
            .Body = ""
            .Attachments.Add Dest.FullName
                    .Send
        End With
        On Error GoTo 0
        .Close savechanges:=False
    End With

    Kill TempFilePath & TempFileName & FileExtStr

    Set OutMail = Nothing
    Set OutApp = Nothing

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

Originally Posted by AlphaFrog

Add this line. Change the Time and Date format to suit.

    Set OutMail = Nothing
    Set OutApp = Nothing
    
    Range("A10").Value = "Shipped " & Format(Now, "hh:mm d/m/yyyy")
    
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

Awesome, thanks a million!!!

If it's not to big of a hassle, and sorry for not asking before - is it possible for it to change the cell-color to light-green?