VBA to hide/ unhide worksheets

i suggest firstly naming your option buttons to something you can work easily with
naming the first one yes and the other ones 1-5 really don't make sense

what you need is a code to check if any of the "yes" options are true

Sub CheckOption()
    
    Dim ctl As Object
    Dim Hide As Boolean 'check to hide site details
    
    Hide = True 'set to hide to true by default
    Application.ScreenUpdating = False 'stop flickering screen
    
    For Each ctl In Worksheets("Job Components").OLEObjects
        If TypeOf ctl.Object Is MSForms.OptionButton Then
            If Application.WorksheetFunction.IsEven(Right(ctl.Name, 1)) Then 'only check the even option buttons
                
                If ctl.Object.Value = True Then 'if any of option "yes" is true then hide to false
                    Hide = False
                End If
            
            End If
        End If
    Next ctl
    
    If Hide = True Then
        Worksheets("Site Details").Visible = False
    Else
        Worksheets("Site Details").Visible = True
    End If
    
    Application.ScreenUpdating = True 'turn screenupdating back on
    
End Sub

then make all the optionbuttons call this sub

if you have more than 9 buttons
i suggest you name 1-9 with a leading zero
ie01,02 and updating the IF to read

If Application.WorksheetFunction.IsEven(Right(ctl.Name, 2))

also you dont have to use even or odd just something readily easy to split
like YesOpt1, NoOpt1,YesOpt2 ...etc then split check left(ctl.name,3) = yes

oh wow you have been busy

you didnt take my advice from Post #4
you now have more than 9 option buttons
running this line of code

If Application.WorksheetFunction.IsEven(Right(ctl.Name, 1))

it will only take the single digit at the end
this would be fine but ...for 10,20,30 these would become zero

this aside i think you have misunderstood how the code works

this for loop

    For Each ctl In Worksheets("Job Components").OLEObjects
        If TypeOf ctl.Object Is MSForms.OptionButton Then
            If Application.WorksheetFunction.IsEven(Right(ctl.Name, 1)) Then 'only check the even option buttons
                
                If ctl.Object.Value = True Then 'if any of option "yes" is true then hide to false
                    Hide = False
                End If
            
            End If
        End If
    Next ctl

goes thru every single oleobject (commandbutton,option button, etc) on the spreadsheet
then checks to see if that object is an option button
then checks the last character of the name of the option button to see if it is even
then checks to see if it is true...
if it passes all these then it applys the "hide" (Boolean which a variable you can set to true or false) to true

sorry i may have confused you

the method i am showing you creates a code which every single button can use instead of having code for every single button individually
the reason for this is if you have to change something you only need to change one set of codes instead of micro change every individual button

you need to map out exactly what set of option buttons does what (ie which button/group of buttons hides which sheet)
then just plot outcomes against each one
i can help you with the syntax but not the outcomes