Excel VBA code importing from text file but between certain key words

[MangoUk]

What I am trying to do is to import from a text file into excel, yet I only want the data from lines between certain key words.

For example below is an extract of the text file.

Please Login or Register  to view this content.

I only need the data between the line starting with "Date" and the line starting with ">LOGOUT"

The contents of the text file repeats itself as it connects to different systems but I only require the information that's is between the two key words so to speak.

I can get the entire text file inputted but really only require that information between the lines.

Any help is greatly appreciated (non programmer)

[jindon]

If you have only one set of data within a txt file then, try

Sub test() 
    Dim fn As String, txt As String, x, y 
    fn = Application.GetOpenFilename("TextFiles,*.txt") 
    If fn = "False" Then Exit Sub 
    txt = CreateObject("Scripting.FileSystemObject").OpenTextFile(fn).ReadAll 
    x = InStr(1, txt, ">DATE", 1) 
    y = InStr(1, txt, ">LOGOUT", 1) 
    If (x > 0) * (y > x) Then 
        txt = Mid$(txt, x, y - x + Len(">LOGOUT") + 1) 
    Else 
        txt = "Something is wrong" 
    End If 
    MsgBox txt 
End Sub  

[MangoUk]

The text file contains multiple instances of the >DATE / >LOGOUT, I just want to capture the info between those markers so to speak, and have it inputted into an excel sheet.

[jindon]

Then

Sub test()
    Dim fn As String, txt As String, m As Object, temp As String, x
    fn = Application.GetOpenFilename("TextFiles,*.txt")
    If fn = "False" Then Exit Sub
    txt = CreateObject("Scripting.FileSystemObject").OpenTextFile(fn).ReadAll
    With CreateObject("VBScript.RegExp")
        .Global = True
        .Pattern = "(>DATE)(.*\r\n(?!\1))+>LOGOUT"
        For Each m In .Execute(txt)
            temp = temp & vbCrLf & m.Value
        Next
    End With
    If Len(temp) Then
        x = Split(Mid$(temp, Len(vbCrLf) + 1), vbCrLf)
        Cells(1).Resize(UBound(x) + 1).Value = Application.Transpose(x)
    Else
        MsgBox "No match"
    End If
End Sub  

[MangoUk]

Thank you so much that worked perfectly