Create checkboxes automatically on userform

Hello everyone
I need a code that enables me to create checkboxes on userform automatically ..
The number of the checkboxes will be Sheets.Count - 1
I mean to rename the created checkboxes with sheets' names except for activesheet

For example: I have four sheets (Main - Report - Data -Result) .. If the Main sheet is the activesheet
In userform intialize I need to create three checkboxes with the caption of each sheet of the other three (Report - Data -Result)

Also I need to create a command button automatically ...
Thanks advanced for help

Try something like this - it relies on having a commandbutton already on the userform (but it moves it to the right place...)

Option Explicit

Private Sub CreateControls()
    Dim ws As Worksheet
    Dim i As Integer
    Dim cBox As MSForms.CheckBox
    Dim iPos As Integer
    
    iPos = 5

    For i = 1 To Worksheets.Count
        Set ws = Worksheets(i)
        If Not ws.Name = "Main" Then
            Set cBox = Me.Controls.Add("Forms.Checkbox.1", "Checkbox" & i, True)
            With cBox
                .Top = iPos
                .Left = 5
                .Width = 80
                .Caption = Worksheets(i).Name
            End With
            iPos = iPos + 15
        End If
    Next i
    With Me.CommandButton1
        .Top = iPos + 5
        .Left = 5
        .Width = 80
        .Caption = "Button Caption"
    End With
    Me.Height = iPos + 60
    Me.Width = 30
End Sub

Private Sub CommandButton1_Click()
    Dim cb As Control
    Dim s As String
    For Each cb In Me.Controls
        If TypeName(cb) = "CheckBox" Then
            s = s & cb.Caption & vbTab & cb.Value & vbCr
        End If
    Next cb
    MsgBox s
End Sub

Private Sub UserForm_Initialize()
    Call CreateControls
End Sub

That's wonderful and awesome Mr. Olly
Exactly as I need .. Working like charm and as expected
Thank you very much
Kind Regards

Hello again
I tried to edit this line

s = s & cb.Caption & vbTab & cb.Value & vbCr

to be like that

            If CB.Value = True Then
                MsgBox CB.Caption
            End If

I checked two of the three checkboxes and it is supposed to display just two messages but I received three messages (two with CB caption and an empty message)
Why I got this empty message?

Originally Posted by YasserKhalil

Hello again
I tried to edit this line

s = s & cb.Caption & vbTab & cb.Value & vbCr

to be like that

            If CB.Value = True Then
                MsgBox CB.Caption
            End If

I checked two of the three checkboxes and it is supposed to display just two messages but I received three messages (two with CB caption and an empty message)
Why I got this empty message?

Did you delete the final msgbox line:

    Next cb
    MsgBox s
End Sub

The coding of created controls can be problematic.
Rather than making checkboxes at run-time, have you considered using a multi-select ListBox with the .ListStyle set to fmListStyleOption?

Thank you very much Mr. Mike
In fact I am so weak at dealing with forms .. Can you provide me a solution to create listbox with sheet names except for active sheet ..
And enables me to select multiplce choices from the list ..
Thanks a lot for advanced help

Originally Posted by YasserKhalil

Thank you very much Mr. Mike
In fact I am so weak at dealing with forms .. Can you provide me a solution to create listbox with sheet names except for active sheet ..
And enables me to select multiplce choices from the list ..
Thanks a lot for advanced help

Here's code which will work for a userform with one listbox (ListBox1) and one Command Button (CommandButton1), listing all worksheets (except [Main] in the listbox, and allowing multiple selections:

Private Sub CreateList()
    Dim ws As Worksheet
    Dim i As Integer
    Dim iPos As Integer

    Me.ListBox1.MultiSelect = fmMultiSelectMulti
    
    For Each ws In ThisWorkbook.Worksheets
        If Not ws.Name = "Main" Then
            Me.ListBox1.AddItem ws.Name
        End If
    Next ws
End Sub

Private Sub CommandButton1_Click()
    Dim i As Integer
    With Me.ListBox1
        If .ListIndex <> -1 Then
            For i = 0 To .ListCount - 1
                If .Selected(i) Then MsgBox .List(i)
            Next i
        End If
    End With
End Sub

Private Sub UserForm_Initialize()
    Call CreateList
End Sub

Thanks a lot Mr. Olly
I'm sorry I didn't notice it ... you are completely right ..
Now It is working well
Thanks again and sorry for disturbing you
Best Regards

Really awesome awesome awesome
Thank you very much for this pretty gift .. I liked it a lot
Thanks again for this unique help
Regards