Find and update table cell

I have a table of data (tblProducts) that has 27 columns of data. Periodically it will be necessary to update the value of a cell in one specific column (col 7).
Rather than having users search the table or bother with a userform, I would like them to be able to locate the cell that requires updating from a small area on the dashboard. I have created a data validation list for the products in the database (column 2 on the database sheet (sheet 2). I also created a VLookup to find the current respective value in column 7. (see image below). The macro I have for the submit button is included below but it results in error 13 Type mismatch. I can't find where the error is. Can anyone help?

Yield.png

Option Explicit

Sub UpdateYieldPercentage()

'declare the variables
Dim findvalue As Range
Dim DataSH As Worksheet
Dim WorkSH As Worksheet
Dim Item As String
Dim Percent As Long

'error handling
On Error GoTo ErrHandler:

'hold in memory and stop screen flicker
Application.ScreenUpdating = False

'set variables
Set DataSH = Sheet2
Set WorkSH = Sheet1
Item = WorkSH.Range("P11").Value
Percent = WorkSH.Range("Q13").Value

'check for values
If Item = "" Or Percent = "" Then
MsgBox "Select a product to update"
Exit Sub
End If

'find the row to edit - Column D holds the values of a data validation list in cell P11
Set findvalue = DataSH.Range("D:D"). _
Find(What:=Item, LookIn:=xlValues, LookAt:=xlWhole)
'update the value
findvalue = Item
findvalue.Offset(0, 6) = Percent ' column 6 is the value that needs to over updated with the value of cell Q13
MsgBox "Yield % for " & Item & " updated", vbOKOnly, "YIELD % UPDATE"

Item = ""         ' Here I was to clear the cells on the dashboard (Sheet1)
Percent = ""

Exit Sub
ErrHandler:
'show error information in a messagebox
MsgBox "An Error has Occurred " & vbCrLf & _
"The error number is: " & Err.Number & vbCrLf & _
Err.Description & vbCrLf & "Please notify Chef Jamie"

End Sub

On which line do you get the error ?

I don't know. It doesn't tell me and doesn't give me the option to go to debug. When I run compile, it shows no error. Is there another way to locate the line?

Thanks. I didn't know that about commenting out the On Error line. Good thing to know. The error occurred at

'check for values
If Item = "" Or Percent = "" Then
MsgBox "Select a product to update"
Exit Sub
End If

Once I removed that, everything worked great except that I get the same error where I want to clear the values from the dashboard using,

Item = ""         ' Here I was to clear the cells on the dashboard (Sheet1)
Percent = ""

How can I accomplish this?

Sub UpdateYieldPercentage()

'declare the variables
Dim Item As String, Percent As Long

'error handling
On Error GoTo ErrHandler:

'hold in memory and stop screen flicker
Application.ScreenUpdating = False

'set variables
Item = Sheet1.Range("P11").Value
Percent = Sheet1.Range("Q13").Value

'check for values
If Item = vbNullString Or Percent = 0 Then
MsgBox "Select a product to update"
Exit Sub
End If

'find the row to edit - Column D holds the values of a data validation list in cell P11
fRow = Application.Match(Item, Sheet2.Columns(4), 0)
Sheet2.Cells(fRow, 9).Value = Percent
MsgBox "Yield % for " & Item & " updated", vbOKOnly, "YIELD % UPDATE"

Sheet1.Range("P11").Value = vbNullString       ' Here I was to clear the cells on the dashboard (Sheet1)
Sheet1.Range("Q13").Value = vbNullString

Exit Sub
ErrHandler:
'show error information in a messagebox
MsgBox "An Error has Occurred " & vbCrLf & _
"The error number is: " & Err.Number & vbCrLf & _
Err.Description & vbCrLf & "Please notify Chef Jamie"
Application.ScreenUpdating = True
End Sub

Perfect!! Thank you so much for your help.

You're welcome and thanks for the rep.