vba to sort multiple sheet tabs in a workbook

Try this code

Sub SortSheets()
    Dim I As Integer, J As Integer

    For I = 1 To Sheets.Count - 1
        For J = I + 1 To Sheets.Count
            If Val(Sheets(I).Name) > Val(Sheets(J).Name) Then
                Sheets(J).Move Before:=Sheets(I)
            End If
        Next J
    Next I
End Sub

Hi JEAN1972,

Try this Code I saw on Mr. Excel some time ago.)

Sub Sort_Active_Book()
Dim i As Integer
Dim j As Integer
Dim iAnswer As VbMsgBoxResult
'
' Prompt the user as which direction they wish to
' sort the worksheets.
'
   iAnswer = MsgBox("Sort Sheets in Ascending Order?" & Chr(10) _
     & "Clicking No will sort in Descending Order", _
     vbYesNoCancel + vbQuestion + vbDefaultButton1, "Sort Worksheets")
   For i = 1 To Sheets.Count
      For j = 1 To Sheets.Count - 1
'
' If the answer is Yes, then sort in ascending order.
'
         If iAnswer = vbYes Then
            If UCase$(Sheets(j).Name) > UCase$(Sheets(j + 1).Name) Then
               Sheets(j).Move After:=Sheets(j + 1)
            End If
'
' If the answer is No, then sort in descending order.
'
        ElseIf iAnswer = vbNo Then
            If UCase$(Sheets(j).Name) < UCase$(Sheets(j + 1).Name) Then
              Sheets(j).Move After:=Sheets(j + 1)
           End If
         
      Next j
   Next i
End Sub

Regards.

Another code (I think for Mr. Jbeaucaire)

Sub SortSheets()
    Dim Arr As Variant, vTemp As Variant, WS As Worksheet
    Dim I As Long, J As Long, buf As String

    For Each WS In Worksheets
        buf = buf & "," & WS.Name
    Next WS
    Arr = Split(Mid(buf, 2, Len(buf)), ",")

    For I = LBound(Arr, 1) To UBound(Arr, 1) - 1
        For J = I + 1 To UBound(Arr, 1)
            If Arr(I) > Arr(J) Then
                vTemp = Arr(I)
                Arr(I) = Arr(J)
                Arr(J) = vTemp
            End If
        Next J
    Next I

    For I = LBound(Arr, 1) To UBound(Arr, 1)
        Sheets(Arr(I)).Move After:=Sheets(Sheets.Count)
    Next I
End Sub

Thanks Mr. Nilem for the code
and may be

Sub Sort_Sheets()
    Dim Sh_Name(99), Nw_Sh(99) As Variant, X As Long, I As Long, J As Long
    Dim exchg
    
    X = Worksheets.Count
    For I = 1 To X
        Sh_Name(I) = Sheets(I).Name
        Nw_Sh(I) = Sh_Name(I)
    Next I
    
    For I = 1 To X
        For J = I + 1 To X
            If Nw_Sh(J) < Nw_Sh(I) Then exchg = Nw_Sh(J): Nw_Sh(J) = Nw_Sh(I): Nw_Sh(I) = exchg
        Next J
    Next I
    
    For I = X To 1 Step -1
        Sheets(Nw_Sh(I)).Move Before:=Sheets(1)
    Next I
End Sub

Hello JEAN1972,

Just for fun. Here is another macro that will sort the worksheets either in ascending (a to z) or descending (z to a) order. This code is a little longer but uses a modified bubble sort which is twice as fast as a normal bubble sort. Doesn't mean much when sorting worksheets but is important when using it to sort lists.

Sub SortWorksheets(Optional ByVal ZtoA As Boolean)

    Dim LB      As Long
    Dim J       As Long
    Dim vList   As Variant
    Dim Sorted  As Boolean
    Dim Temp    As Variant
    Dim UB      As Long
        
    ' Written:  July 15, 2016
    ' Author:   Leith Ross
    ' Summary:  Sorts worksheets in ascending or descending alpahbetical order.
    '           Default is ascending order (ZtoA is False).

        ReDim vList(1 To ThisWorkbook.Worksheets.Count)
        
        For n = 1 To ThisWorkbook.Worksheets.Count
            vList(n) = ThisWorkbook.Worksheets(n).Name
        Next n
        
        LB = LBound(vList)
        UB = UBound(vList)
        
            Do
                Sorted = True
                
                For J = LB To UB - 1
                    If ZtoA Xor StrComp(vList(J), vList(J + 1), vbTextCompare) = 1 Then
                        Temp = vList(J + 1)
                        vList(J + 1) = vList(J)
                        vList(J) = Temp
                        
                        Sorted = False
                    End If
                Next J
                
                UB = UB - 1
            Loop Until Sorted Or UB < 1
        
        For n = 1 To ThisWorkbook.Worksheets.Count - 1
            ThisWorkbook.Worksheets(vList(n)).Move Before:=ThisWorkbook.Worksheets(n)
        Next n
        
End Sub

Try

Sub Sort_Sheets_Winon()
    Dim I As Integer
    Dim J As Integer
    Dim iAnswer As VbMsgBoxResult

    iAnswer = MsgBox("Sort Sheets In Ascending Order?" & Chr(10) & "Clicking No Will Sort In Descending Order", vbYesNoCancel + vbQuestion + vbDefaultButton1, "Sort Worksheets")
    For I = 1 To Sheets.Count
        For J = 1 To Sheets.Count - 1
            If iAnswer = vbYes Then
                If UCase$(Sheets(J).Name) > UCase$(Sheets(J + 1).Name) Then
                    Sheets(J).Move After:=Sheets(J + 1)
                End If
            ElseIf iAnswer = vbNo Then
                If UCase$(Sheets(J).Name) < UCase$(Sheets(J + 1).Name) Then
                    Sheets(J).Move After:=Sheets(J + 1)
                End If
            End If
        Next J
    Next I
End Sub