Excel VBA Macros validations

[ThiliSuper]

Need a validations like below,

e.g. V-b0982

When user enters first character as alphabetic(except capital V) or numeric value or special character -- Validation message should be "First character should be V"
When user enters second character as special character(except -) or numeric value or alphabetic -- Validation message should be "second character should be -"
When user enters third character as special character or numeric value-- Validation message should be "third character should be alphabetic"
When user enters last four characters as special character or alphabetic -- Validation message should be "last four characters should be numeric values"

[karedog]

Maybe :

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim rng As Range, strMsg As String
  Set rng = Intersect(Target, Range("C3:C" & Me.Rows.Count))  'Change "C3:C" as needed
  If Not rng Is Nothing Then
     If rng.Cells.Count = 1 Then
        If Len(rng.Value) = 7 Then
           If Mid$(rng.Value, 1, 1) <> "V" Then strMsg = strMsg & "First character should be V" & vbCrLf
           If Mid$(rng.Value, 2, 1) <> "-" Then strMsg = strMsg & "Second character should be -" & vbCrLf
           If Not Mid$(rng.Value, 3, 1) Like "[A-z]" Then strMsg = strMsg & "Third character should be alphabetic" & vbCrLf
           If Not Mid$(rng.Value, 4, 4) Like "####" Then strMsg = strMsg & "Last four characters should be numeric values" & vbCrLf
        Else
           If Len(rng.Value) <> 0 Then strMsg = "Incorrect length" & vbCrLf
        End If
        If Len(strMsg) Then MsgBox strMsg
     End If
  End If
End Sub

[bakerman2]

@ ThiliSuper

Why not continue in your other thread so people can see other answers already given.

http://www.excelforum.com/showthread...t=#post4487971

[FDibbins]

Welcome to the Forum, unfortunately:

This is a duplicate post and as such does not comply with Rule 5 of our forum rules. This thread will now be closed, you may continue in your other thread.

Thread Closed.

http://www.excelforum.com/showthread...t=#post4487971