Optimize long code

The first thing I would do is rationalize the names of the controls on the userform.
You could use code like this. Note that this code is to be in a normal module and run at design time. Once all the controls have decent names it can be discarded. The names of the controls will have been permanently changed.

You'll have to change the StartControlName and the Prefix for each row of your grid.
Similar code could take care of the headers and the total row.

Sub test()
    Dim thisLabel As MSForms.Control
    Dim nextLabel As MSForms.Control
    Dim colIndex As Long
    Dim prefix As String
    Dim StartControlName As String
    
    StartControlName = "Label1701"
    prefix = "lblGrid1_"
    colIndex = 1
    
    With ThisWorkbook.VBProject.VBComponents("Userform1").Designer

        Set thisLabel = .Controls(StartControlName)
        
        Do
            thisLabel.Name = prefix & colIndex
            colIndex = colIndex + 1
            Set nextLabel = NextToRight(thisLabel)
        Loop Until nextLabel Is Nothing
    End With
End Sub

Function NextToRight(aControl As MSForms.Control) As MSForms.Control
    Dim oneControl As MSForms.Control
    Dim RightVal As Single
    RightVal = 10000
    For Each oneControl In aControl.Parent.Controls
        If (Abs(oneControl.Top - aControl.Top) < 4) Then
            If aControl.Left < oneControl.Left Then
                If oneControl.Left < RightVal Then
                    Set NextToRight = oneControl
                    RightVal = oneControl.Left
                End If
            End If
        End If
    Next oneControl
End Function

Public ChangeFlag As Boolean
Public Filled As Variant

Private Sub cboMonth_Change()

'This skips this Macro when the Userform is first activated
If ChangeFlag = True Then GoTo Quit

'This is required to store the row numbers of the data on the sheet
Pos = Split("6,11,14,23,25,27", ",")

'Is this row empty?
If Filled(cboMonth.ListIndex) = 0 Then

'Fill Row
Filled(cboMonth.ListIndex) = 1

For Count = 0 To 5

'Load the Textbox
Me.Controls("Textbox" & Count + cboMonth.ListIndex * 6 - 5).Value = Sheets(1).Cells(Pos(Count), cboMonth.ListIndex + 1).Value

'Add the New Data to the Summing Text Box at the bottom of the Userform
T1 = Me.Controls("Textbox" & 73 + Count).Value + Sheets(1).Cells(Pos(Count), cboMonth.ListIndex + 1).Value
Me.Controls("Textbox" & 73 + Count).Value = T1

Next

Else

'Clear Row
Filled(cboMonth.ListIndex) = 0

For Count = 0 To 5

'Load the Textbox
Me.Controls("Textbox" & Count + cboMonth.ListIndex * 6 - 5).Value = 0

'Subtract the New Data from the Summing Text Box at the bottom of the Userform
T1 = Me.Controls("Textbox" & 73 + Count).Value - Sheets(1).Cells(Pos(Count), cboMonth.ListIndex + 1).Value
Me.Controls("Textbox" & 73 + Count).Value = T1

Next

End If

Quit:

End Sub

Private Sub UserForm_Initialize()

'This is my database to log which months have been added to the Userform
Filled = Split("0,0,0,0,0,0,0,0,0,0,0,0", ",")

ChangeFlag = True
cboMonth.List = Array("Select", "JANUARY", "FEBRUARY", "MARCH", "APRIL", "MAY", "JUNE", "JULY", "AUGUST", "SEPTEMBER", "OCTOBER", "NOVEMBER", "DECEMBER")
cboMonth.ListIndex = 0
ChangeFlag = False
End Sub

I've renamed the controls, added Labels to the Bus and Taxi columns on the user form.

I think that this will do what you want.

Option Explicit

Private Sub cboMonth_Change()
    Dim i As Long, j As Long
    For i = 1 To 12
        For j = 1 To 6
            GridLabel(i, j).Caption = vbNullString
        Next j
    Next i
    If 0 < cboMonth.ListIndex Then
        Call FillGridRow(cboMonth.ListIndex)
    End If
    Call fillTotals
End Sub

Sub fillTotals()
    Dim j As Long
    For j = 1 To 6
        Me.Controls("lblTotal" & j).Caption = TotalValue(cboMonth.Text, j)
    Next j
End Sub
Sub FillGridRow(rowNum As Long)
    Dim i As Long
    For i = 1 To 6
        GridLabel(rowNum, i).Caption = GridValue(rowNum, i)
    Next i
End Sub

Function GridValue(rIndex As Long, cIndex As Long) As Variant
    Dim MonthVal As String
    Dim ColHeader As String
    Dim MonthCol As Range
    Dim HeaderRow As Range
    
    GridValue = vbNullString
    
    MonthVal = Trim(Me.Controls("lblMonth" & Format(rIndex, "00")).Caption)
    ColHeader = Trim(Me.Controls("lblHeader" & cIndex).Caption)
    
    With Hoja1.Cells
        Set MonthCol = .Find(MonthVal, lookat:=xlWhole, MatchCase:=False)
        Set HeaderRow = .Find(ColHeader, lookat:=xlWhole, MatchCase:=False)
    End With
    
    If Not (MonthCol Is Nothing Or HeaderRow Is Nothing) Then
        GridValue = Application.Intersect(MonthCol.EntireColumn, HeaderRow.EntireRow).Value
    End If
End Function

Function TotalValue(MonthVal As String, cIndex As Long) As Variant
    Dim ColHeader As String
    Dim MonthCol As Range
    Dim HeaderRow As Range
    
    TotalValue = vbNullString
    
    ColHeader = Trim(Me.Controls("lblHeader" & cIndex).Caption) & " ACC"
    
    With Hoja1.Cells
        Set MonthCol = .Find(MonthVal, lookat:=xlWhole, MatchCase:=False)
        Set HeaderRow = .Find(ColHeader, lookat:=xlWhole, MatchCase:=False)
    End With
    
    If Not (MonthCol Is Nothing Or HeaderRow Is Nothing) Then
        TotalValue = Application.Intersect(MonthCol.EntireColumn, HeaderRow.EntireRow).Value
    End If
End Function

Function GridLabel(rIndex As Long, cIndex As Long) As MSForms.Label
    Set GridLabel = Me.Controls("lblGrid" & rIndex & "_" & cIndex)
End Function


Private Sub UserForm_Initialize()

cboMonth.List = Array("Select", "JANUARY", "FEBRUARY", "MARCH", "APRIL", "MAY", "JUNE", "JULY", "AUGUST", "SEPTEMBER", "OCTOBER", "NOVEMBER", "DECEMBER")
cboMonth.ListIndex = 0

End Sub