elliminate commas, semicolons, colons, etc. from a string

Few ways.
e.g

Sub ReplaceMethod()
    For Each e In Array(",", ":", ";")
        Columns(1).Replace e, "", 2
    Next
End Sub

Sub myReplaceFunc()
    MsgBox Replace (Replace (Replace ("This, here: is; my string", ",", ""), ":", ""), ";", "")
End Sub

Sub RegX()
    With CreateObject("VBScript.RegExp")
        .Global = True
        .Pattern = "[,:;]"
        MsgBox .Replace("This, here: is; my string", "")
    End With
End Sub

Here's an ALL CAP version of jindon's REPLACEMETHOD :

Option Explicit
Function UStrip(sWord As String) As String
'This function takes a string outputs an uppercase equivalent with
'  all characters stripped but numbers and letters
'Uppercase is used since it is a better function with "Find" since case becomes immaterial
    Dim x As Long
    Dim sCharacter As String
    sWord = UCase(sWord)  'Convert to Uppercase
    UStrip = "" 'Set originall as null
    For x = 1 To Len(sWord) 'Act on each letter
        sCharacter = Mid(sWord, x, 1)
        If Asc(sCharacter) >= 65 And _
            Asc(sCharacter) <= 90 Then '65-90 are ASCII "A"-"Z"
            'sCharacter is a LETTER
            UStrip = UStrip & sCharacter
        ElseIf sCharacter = " " Then
            'sCharacter is a space
            UStrip = UStrip & sCharacter
        ElseIf Asc(sCharacter) >= 48 And _
            Asc(sCharacter) <= 57 Then '48-57 are ASCII "0"-"9"
            'sCharacter is a "text-NUMBER"
            UStrip = UStrip & sCharacter
      End If
    Next x
End Function

Sub StripItOut()
Dim A1 As String
A1 = Sheets("Sheet1").Range("A1").Value
Sheets("Sheet1").Range("A3").Value = UStrip(A1)
End Sub