2D VBA array

Hi,

You don't want to loop through each item in the array, only each row, so you can do something like this

Sub morearrays()
Dim lrow As Long
Dim secondarray() As Variant
Dim x As Long
lrow = Cells(Rows.Count, 1).End(xlUp).Row
secondarray = Range("a2:b" & lrow).Value

For x = 1 to Ubound(secondarray, 1)
Cells(x + 1, "c").Value = secondarray(x, 1) & " " & secondarray(x, 2)
Next


End Sub

It would be more efficient to write the results into another array and load that into column C at the end

Sub morearrays()
Dim lrow As Long
Dim secondarray() As Variant
Dim thirdArray()
Dim x As Long
lrow = Cells(Rows.Count, 1).End(xlUp).Row
secondarray = Range("a2:b" & lrow).Value

' resize new array to same number of rows and one column
Redim thirdArray(1 to ubound(secondarray, 1), 1 to 1)

For x = 1 to Ubound(secondarray, 1)
' load into array instead of cells
thirdArray(x, 1) = secondarray(x, 1) & " " & secondarray(x, 2)
Next

' now populate column C
Range("C2:C" & lrow).Value = thirdArray

End Sub

Late to the party but here's a variation on a theme using just the one array:

Option Explicit

Sub CombineNames()

Dim ws As Worksheet
Dim lLR As Long, i As Long
Dim vArr

Set ws = Sheet1

With ws
    lLR = .Range("A" & .Rows.Count).End(xlUp).Row
    vArr = .Range("A2:B" & lLR)
    ReDim Preserve vArr(LBound(vArr, 1) To UBound(vArr, 1), LBound(vArr, 2) To UBound(vArr, 2) + 1)
    
    For i = LBound(vArr, 1) To UBound(vArr, 1)
        vArr(i, 3) = vArr(i, 1) & " " & vArr(i, 2)
    Next 'i
    
    .Range("A2:C" & lLR) = vArr
End With

End Sub