Variable Length Array does not bring correct data

Hi

I want to create variable length array which should bring different data at each condition.

My code is

Sub Test()
Dim r As Integer
Dim c As Integer

r = Application.WorksheetFunction.CountIf(Range("A1", Range("A1").End(xlDown)), Cells(1, 10))
c = Range("A1", Range("A1").End(xlToRight)).Columns.Count


ReDim temparray(1 To r, 1 To c)

For ar = 1 To r
    For ac = 1 To c
        For i = 1 To Range("A5", Range("A5").End(xlDown)).Rows.Count
            If Cells(1, 10) = Cells(i, 1) Then
                temparray(ar, ac) = Cells(i, ac)
            End If
        Next i
    Next ac
Next ar

Range(Cells(1, 6), Cells(r, 5 + c)) = temparray

End Sub

But I could not understand at which part I did mistake, because code brings data only one of criteria. Please correct me. I want to understand the code.

Thank you in advance

Sub Test()
    Dim r As Long
    Dim c As Long
    Dim ar As Long
    Dim ac As Long
    Dim i As Long
    Dim temparray As Variant
    
    r = Application.WorksheetFunction.CountIf(Range("A1", Range("A1").End(xlDown)), Cells(1, 10))
    c = Range("A1").End(xlToRight).Column
    ReDim temparray(1 To r, 1 To c)
    
    For ar = 1 To Range("A1").End(xlDown).Row
        If Cells(1, 10) = Cells(ar, 1) Then
            i = i + 1
            For ac = 1 To c
                temparray(i, ac) = Cells(ar, ac)
            Next ac
        End If
    Next ar
    
    Cells(1, 6).Resize(UBound(temparray, 1), UBound(temparray, 2)).Value = temparray
    
End Sub

Thank you very much.

Can you tell me what was my mistake?

There were several mistakes.

• Three nested loops when only two are needed (rows and columns)
• You tested the criteria for every cell (all rows and all columns) when you only need to test the criteria for each row in the first column.
• Your line For ar = 1 To r only looped through 4 rows as r was not the number of rows in your data. It was the count of the criteria match.