IF-THEN-ELSE - how i reduce size of the prodedure

[karurkumar]

hai in below code there any possibility to reduce the size of the prodedure.
i am new to VBA trying to learn the skill

Sub RSIDSTOBUYSELL()
 With Application
   Application.Calculation = xlCalculationManual
   Application.ScreenUpdating = False
   Application.DisplayStatusBar = False
   Application.EnableEvents = False
   Application.PrintCommunication = False
   End With

Dim I As Long
Dim IRow As Long
Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Select
IRow = Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("H" & Rows.Count).End(xlUp).Row
For I = 20600 To IRow

    If Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("S" & I).Value < 50 And _
    Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("U" & I).Value < 50 And _
    Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("T" & I).Value > 80 Then
    Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("L" & I).Value = "next LL is BUY"
    Else: Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("L" & I).Value = " "

If Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("S" & I).Value > 50 And _
Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("U" & I).Value > 50 And _
Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("T" & I).Value < 20 Then
Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("L" & I).Value = "next HH is SELL"
Else: Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("L" & I).Value = " "

If Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("S" & I).Value > 30 And _
Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("U" & I).Value < 20 And _
Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("T" & I).Value < 20 Then
Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("L" & I).Value = "BULLISH trend"
Else: Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("L" & I).Value = " "

     If Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("S" & I).Value < 70 And _
     Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("U" & I).Value > 80 And _
     Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("T" & I).Value > 80 Then
     Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("L" & I).Value = "DOWN trend"
     Else: Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("L" & I).Value = " "

  End If
  End If
  End If
  End If
  Next I
  ''Call DSRBSCOLOR
   With Application
        .Calculation = xlCalculationAutomatic
        .ScreenUpdating = True
        .DisplayStatusBar = True
        .EnableEvents = True
        .PrintCommunication = True
    End With

End Sub

[Special-K]

No VBA expert but there's a command called CASE that may solve this

[cytop]

One way to get rid of excess statements is by using 'With', as you have done near the end of the posted block

Option Explicit

Sub RSIDSTOBUYSELL()
   With Application
      Application.Calculation = xlCalculationManual
      Application.ScreenUpdating = False
      Application.DisplayStatusBar = False
      Application.EnableEvents = False
      Application.PrintCommunication = False
   End With

   Dim I                As Long
   Dim IRow             As Long
   Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Select
   IRow = Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1").Range("H" & Rows.Count).End(xlUp).Row

   With Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1")
      For I = 20600 To IRow

         If .Range("S" & I).Value < 50 And _
            .Range("U" & I).Value < 50 And _
            .Range("T" & I).Value > 80 Then
            .Range("L" & I).Value = "next LL is BUY"
         Else: .Range("L" & I).Value = " "

            If .Range("S" & I).Value > 50 And _
               .Range("U" & I).Value > 50 And _
               .Range("T" & I).Value < 20 Then
               .Range("L" & I).Value = "next HH is SELL"
            Else: .Range("L" & I).Value = " "

               If .Range("S" & I).Value > 30 And _
                  .Range("U" & I).Value < 20 And _
                  .Range("T" & I).Value < 20 Then
                  .Range("L" & I).Value = "BULLISH trend"
               Else: .Range("L" & I).Value = " "

                  If .Range("S" & I).Value < 70 And _
                     .Range("U" & I).Value > 80 And _
                     .Range("T" & I).Value > 80 Then
                     .Range("L" & I).Value = "DOWN trend"
                  Else: .Range("L" & I).Value = " "

                  End If
            End If
         End If
      End If
   Next I
   End With
   
   ''Call DSRBSCOLOR
   With Application
      .Calculation = xlCalculationAutomatic
      .ScreenUpdating = True
      .DisplayStatusBar = True
      .EnableEvents = True
      .PrintCommunication = True
   End With

End Sub

Although it does not help shorten code, you should learn to indent. It helps make the logic of the code clearer

[CK76]

Further to what cytop did, you can shorten code a bit more.

1. You don't need select the sheet as code specifies which sheet to run code on.

2. Your If statements can be combined into one If statement with Elseif arguments. Reducing "Else.." to single line, instead of repeating at each If statement.

3. Move Optimization codes to another sub routine and call it at start and end (using Boolean switch).

Code becomes something like...

Option Explicit

Sub RSIDSTOBUYSELL()
    Dim I                As Long
    Dim IRow             As Long
    
    OptimizeCode True
    With Workbooks("01A  data 1 MT --1.xlsm").Sheets("DATAIND1")
        IRow = .Range("H" & Rows.Count).End(xlUp).Row
        For I = 20600 To IRow
            If .Range("S" & I).Value < 50 And _
             .Range("U" & I).Value < 50 And _
             .Range("T" & I).Value > 80 Then
                .Range("L" & I).Value = "next LL is BUY"
            ElseIf .Range("S" & I).Value > 50 And _
             .Range("U" & I).Value > 50 And _
             .Range("T" & I).Value < 20 Then
                .Range("L" & I).Value = "next HH is SELL"
            ElseIf .Range("S" & I).Value > 30 And _
             .Range("U" & I).Value < 20 And _
             .Range("T" & I).Value < 20 Then
             .Range("L" & I).Value = "BULLISH trend"
            ElseIf .Range("S" & I).Value < 70 And _
             .Range("U" & I).Value > 80 And _
             .Range("T" & I).Value > 80 Then
             .Range("L" & I).Value = "DOWN trend"
            Else: .Range("L" & I).Value = " "
            End If
        Next I
   End With
   
   ''Call DSRBSCOLOR
   OptimizeCode False
End Sub

Sub OptimizeCode(switch As Boolean)
   With Application
      .Calculation = IIf(switch, xlCalculationManual, xlCalculationAutomatic)
      .ScreenUpdating = Not (switch)
      .DisplayStatusBar = Not (switch)
      .EnableEvents = Not (switch)
      .PrintCommunication = Not (switch)
   End With
End Sub