Key inventory VBA help needed

In your example workbook, the VBA modules are password protected

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim v As Variant, ws As Worksheet
    Set ws = Sheet2
    If Target.Count > 1 Then Exit Sub
    If Target.Value = "" Then Exit Sub
    Select Case Target.Address(0, 0)
        Case "A2", "A4"
            If Range("A2").Value <> "" Then
                v = Application.Match(Range("A2").Value, ws.Range("B:B"), 0)
                If IsError(v) Then
                    MsgBox "Cannot match Key Number: " & Target.Value, vbExclamation, "Invalid Key Number"
                Else
                    ws.Range("E" & v).Value = Date
                    ws.Range("F" & v).ClearContents
                    ws.Range("C" & v) = Range("A4").Value
                End If
            End If
        Case "A9"
            v = Application.Match(Target.Value, ws.Range("B:B"), 0)
            If IsError(v) Then
                MsgBox "Cannot match Key Number: " & Target.Value, vbExclamation, "Invalid Key Number"
            Else
                If ws.Range("E" & v).Value = "" Then
                    MsgBox "No checkout date.", , "Invalid Entry"
                Else
                    ws.Range("F" & v).Value = Date
                    Range("A11").Value = ws.Range("C" & v).Value
                End If
            End If
    End Select
End Sub