Userform - Combobox

[atalante_]

Hello,

I'm fairly new in Excel and trying to create an userform to fill a table.
I have 1 combobox and 4 textboxes to fill a table and right now I'm only able to fill the first row of the table. But, I am still trying to fill the other rows in table based on my combobox selection. Please find attached the SS.excel.jpg

What I'm trying to do?

1. Select "Motorcycles"
2. Fill 4 cells in userform (Percent of ADT etc.)
3. Add these values to table (C12, D12, E12, F12 respectively)
4. Select "Passenger Cars" (2nd option in my combobox)
5. Fill again the 4 cells in userform (Percent of ADT etc.)
6. Add these values to table (C13, D13, E13, F13 respectively)

Could you please help me to do that?

Thank you very much in advance.

[mike7952]

Attach a sample workbook. Make sure there is just enough data to demonstrate your need. Include a BEFORE sheet and an AFTER sheet in the workbook if needed to show the process you're trying to complete or automate. Make sure your desired results are shown, mock them up manually if necessary.

Remember to desensitize the data.

Click on GO ADVANCED and then scroll down to Manage Attachments to open the upload window.

[atalante_]

Thanks for your answer. I uploaded a sample file.

[mike7952]

Here's your form code for Form2

Private Sub CmdAdd2_Click()
Dim whatrow As Long
 
 With Worksheets("Traffic")
    On Error Resume Next
    whatrow = Application.Match(ComboBox1.Value, .Columns(2), 0)
    On Error goto 0
    If whatrow > 0 Then
        .Cells(whatrow, "C").Value = TextBox1.Value
        .Cells(whatrow, "D").Value = TextBox2.Value
        .Cells(whatrow, "E").Value = TextBox3.Value
        .Cells(whatrow, "F").Value = TextBox4.Value
    Else
        MsgBox ComboBox1.Value & " Not found"
    End If
 End With
End Sub

Private Sub CmdClear2_Click()
TextBox1 = ""
TextBox2 = ""
TextBox3 = ""
TextBox4 = ""
End Sub

Private Sub CmdClose2_Click()
Unload Me
End Sub

Private Sub ComboBox1_Change()
Dim whatrow As Long
 
 With Worksheets("Traffic")
    On Error Resume Next
    whatrow = Application.Match(ComboBox1.Value, .Columns(2), 0)
    On Error goto 0
    If whatrow > 0 Then
        TextBox1.Value = .Cells(whatrow, "C").Value
        TextBox2.Value = .Cells(whatrow, "D").Value
        TextBox3.Value = .Cells(whatrow, "E").Value
        TextBox4.Value = .Cells(whatrow, "F").Value
    Else
        TextBox1.Value = ""
        TextBox2.Value = ""
        TextBox3.Value = ""
        TextBox4.Value = ""
    End If
 End With
End Sub

[atalante_]

I've been struggling with this during 2 days, you are great Mike!
Thank you so much!

[mike7952]

No problem there a many other ways to do this also.

If that takes care of your original question, please select Thread Tools from the menu link above and mark this thread as SOLVED. Thanks.