function argument variables

Look into the Worksheet. (or Application.) Evaluate method.

You aren't actually passing an equation, but the result of it, so this should suffice

Function SIGMA(n As Integer, i As Integer, Equation) As Double
    Dim a As Integer
    For a = i To n
        SIGMA = SIGMA + Equation
    Next a
End Function

I am trying to have an incremented input (i) be run through an expression (Equation) (n) times then have all (n) outputs be added together.
it should be something like this:
=SIGMA(9,1,2*i)
^^type in cell^^
(2*1)+(2*2)+(2*3)+(2*4)+(2*5)+(2*6)+(2*7)+(2*8)+(2*9)
^^Calculation Steps^^
=90
^^Returns^^

Hello Batnoob,

Will the user be able to change the equation when using this function?

Originally Posted by Leith Ross

Hello Batnoob,

Will the user be able to change the equation when using this function?

Yes, the user should be able to change the equation. the equation is an argument so user should be able to input anything e.g.
=SIGMA(9,1,2*i)
=SIGMA(12,-7,4*i+6)
etc.

Function SIGMA(ByVal n As Long, ByVal i As Long, ByVal Equation As String) As Double
    Dim a
    For a = i To n
        SIGMA = SIGMA + Evaluate("=" & Equation)
    Next a
End Function

If Equation is passed as a string, it must be entered as such - with QUOTES. In a cell: =SIGMA(5,1,"4*i+6")
And here's the UDF (which assumes you actually wanted to use the incremented "a" value, not the static "i" value):

Function SIGMA(ByVal n As Long, ByVal i As Long, ByVal Equation As String) As Double
    Dim EQ As String, Accum As Double, a As Double
    For a = i To n
        EQ = Replace(Equation, "i", CStr(a))
        Accum = Accum + Evaluate(EQ)
    Next a
    SIGMA = Accum
End Function

BTW, your original code was needlessly recursive. Just accumulate the value in the loop and assign it to SIGMA after.

Originally Posted by leelnich

BTW, your original code was needlessly recursive. Just accumulate the value in the loop and assign it to SIGMA after.

There was no recursion in the original code. This line

Sigma = Sigma + S

is not recursive- Sigma is effectively a local variable not a function call.

Originally Posted by xlnitwit

Sigma = Sigma + S
is not recursive- Sigma is effectively a local variable not a function call.

I tested that- and you are correct. But I confess to not understanding why. Is it because the syntax lacks parenthesis - or parameters for that matter?

Regardless of the answer, the extra variable can be dropped:

Function SIGMA(ByVal n As Long, ByVal i As Long, ByVal Equation As String) As Double
    Dim EQ As String, a As Double
    For a = i To n
        EQ = Replace(Equation, "i", CStr(a))
        SIGMA = SIGMA + Evaluate(EQ)
    Next a
End Function

Yes, without the brackets it's just a variable- as when you use it to return the value at the end.

Thanks for pointing it out. I never really considered that implication when using functions - some recursive - in the past.

You're welcome.

I like your avatar- I often feel like hitting my laptop like that to make the code do what I want.

Like iron smithing, the process of forging code is learned by observing the properties of your raw materials ... or something like that.

i am so confused. so i want the user to be able to type in the cell

Formula:

=SIGMA(2,1,2*i)

and it calculates (in this case to 6, because 2*1+2*2=6), but instead everything i've gotten returns #VALUE
does the user have to wrap the variable that they put in the equation with special symbols to correctly pass it to VBA (kind of like batch %var% or POSH's $var)?

As leelnich said, they will have to put the equation itself in quotes.

This goes in a cell:
=SIGMA(2,2,"2*i")

...and this is your User-Defined Function (macro):

Function SIGMA(ByVal n As Long, ByVal i As Long, ByVal Equation As String) As Double
    Dim EQ As String, a As Double
    For a = i To n
        EQ = Replace(Equation, "i", CStr(a))
        SIGMA = SIGMA + Evaluate(EQ)
    Next a
End Function

thank you both! +1 reputation each.

You're most welcome, thank you for the rep! If concluded, please mark your thread as SOLVED (Thread Tools above post #1). Regards – Lee