IF cell contains * or * delete entire Row

Trying to assertain why this macro will not work.
If Not IsError(.Value) works fine with one item
but If Not IsError(Application.Match(.Value, _ - will not delete the row items from the list in col A

What am I missing - End If is active with If Not IsError(.Value) but compile error end if w/o block if

Sub Delete_Row_IfCellContainsCertainText()
    Dim Firstrow As Long
    Dim Lastrow As Long
    Dim Lrow As Long
    Dim CalcMode As Long
    Dim ViewMode As Long

    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
    End With
    With ActiveSheet
        .Select

        ViewMode = ActiveWindow.View
        ActiveWindow.View = xlNormalView
        .DisplayPageBreaks = False

        Firstrow = .UsedRange.Cells(1).Row
        Lastrow = .UsedRange.Rows(.UsedRange.Rows.Count).Row
        For Lrow = Lastrow To Firstrow Step -1
            With .Cells(Lrow, "A")
  '              If Not IsError(.Value) Then
  '                  If .Value Like "*CSB*" Then .EntireRow.Delete
                If Not IsError(Application.Match(.Value, _
                Array("*CSB *", "*Hanover County Community Svcs Board", "*Valley Community Service Board", "*District Three Transportation", "*MEOC *", "*Appalachian Agency For Senior Citizens, Inc.", "*Behavioral Health Associates", "*Franklin Co. Dept. of Aging", "*New River Valley Senior Services", "*Piedmont Senior Resources *", "*Lake Country AAA Inc.", "*Bay Aging - Bay Transit", "*Senior Services of Southeastern VA", "GAS*", "GR *", "VD *", "* PT *"), 0)) Then .EntireRow.Delete
  '              End If
            End With
        Next Lrow
    End With
    
    ActiveWindow.View = ViewMode
    With Application
        .ScreenUpdating = True
        .Calculation = CalcMode
    End With
End Sub

I get no compile error with your code.
You have 3 lines commented out. Are you sure the last of those lines was a comment when you got the compile error?

You don't need it. Leave it as a comment.

I attached a file

How about

Sub Delete_Row_IfCellContainsCertainText()
    Dim Firstrow As Long
    Dim Lastrow As Long
    Dim Lrow As Long
    Dim CalcMode As Long
    Dim ViewMode As Long
    Dim Ary As Variant
    Dim i As Long
   
   Ary = Array(" * CSB * ", "*Hanover County Community Svcs Board", "*Valley Community Service Board", "*District Three Transportation", "*MEOC *", "*Appalachian Agency For Senior Citizens Inc.", "*Behavioral Health Associates", "*Franklin Co. Dept. of Aging", "*New River Valley Senior Services", "*Piedmont Senior Resources *", "*Lake Country AAA Inc.", "*Bay Aging - Bay Transit", "*Senior Services of Southeastern VA", "GAS*", "GR *", "VD *", "* PT *")
    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
    End With
    With ActiveSheet

        ViewMode = ActiveWindow.View
        ActiveWindow.View = xlNormalView
        .DisplayPageBreaks = False

        Firstrow = .UsedRange.Cells(1).Row
        Lastrow = .UsedRange.Rows(.UsedRange.Rows.Count).Row
        For Lrow = Lastrow To Firstrow Step -1
            With .Cells(Lrow, "A")
                For i = 0 To UBound(Ary)
                  If .Value Like Ary(i) Then
                     .EntireRow.Delete
                      Exit For
                   End If
               Next i
            End With
        Next Lrow
    End With
    
    ActiveWindow.View = ViewMode
    With Application
        .ScreenUpdating = True
        .Calculation = CalcMode
    End With
End Sub

Fantastic - Thanks!
Thank you also for placing into an array - helps me know how for future use.
Appreciated
jim

Glad to help & thanks for the feedback