Need to save a copy of a workbook to another location

I use a workbook that is updated daily. At the end of the shift, I need to save a copy (with macros intact) to another file location. The name of the file will need to be the contents of cell Y2 on the master document. I also need the master to remain open and not close immediately after saving. I've only been able to find tutorials that save without macros and that close the master immediately after saving.

Sub Save_Copy()
Dim sSavePath As String, sFileName As String

'GET SAVE PATH
sSavePath = vbNullString: sSavePath = "\\ant\dept-na\SAT1\Support\Department\2018\End of Shift\EOS_PILOT\"
If sSavePath = vbNullString Then GoTo ERROREXIT

'GET FILE NAME
sFileName = vbNullString: sFileName = CStr(ActiveSheet.Cells(2, 25).Value)
If sFileName = vbNullString Then GoTo ERROREXIT

'SAVE
ActiveWorkbook.SaveAs Filename:=sFileName, FileFormat:=xlOpenXMLWorkbookMacroEnabled

ERROREXIT:

End Sub

This is what I have currently, but it still closes the master without saving and leaves me in the open copied file which it deposits in my documents instead of the designated file.

Try This. You'll need Microsoft Scripting Runtime enabled and be aware that it will overwrite a file of the same name in the save location.

Sub TEST()
Dim sMasterFullName As String, sSavePath As String, sSaveFullName As String
Dim fso As Object

'SAVE ACTIVE WORKBOOK TO ITS CURRENT LOCATION
ActiveWorkbook.Save

'GET ACTIVE WORKBOOK FULL NAME
sMasterFullName = vbNullString: sMasterFullName = ActiveWorkbook.FullName
If sMasterFullName = vbNullString Then GoTo ERROREXIT

'GET SAVE PATH
sSavePath = vbNullString: sSavePath = "INSERT SAVE PATH HERE"
If sSavePath = vbNullString Then GoTo ERROREXIT

'GET SAVE FULL NAME
sSaveFullName = vbNullString: sSaveFullName = sSavePath & CStr(ActiveSheet.Cells(2, 25).value)
If sSaveFullName = vbNullString Then GoTo ERROREXIT

'COPY FROM ACTIVE WORKBOOK'S CURRENT LOCATION TO SAVE PATH
Set fso = Nothing: Set fso = VBA.CreateObject("Scripting.FileSystemObject")
If fso Is Nothing Then GoTo ERROREXIT
Call fso.CopyFile(sMasterFullName, sSaveFullName)

ERROREXIT:
Set fso = Nothing

End Sub

Looks like that's gonna work. Only thing now is that the copied version isn't recognized as an excel document.

Be sure the name of the file in cell Y2 has the file type on the right side of the string (probably .xlsm in your case).

Works! thanks