Mark Cells if Match found in Sheet2

Hi all,
I have the below code that marks (turns bold and colored yellow) the Cells in Sheet1 (Column1) if there is a match on Sheet 2 (Column1).
It is working okay but I need some help to tweak it a bit.

Sub FindMatch()
    
    Dim i As Long, x, y
    With Sheets("Sheet1").[B5].CurrentRegion
        .Offset(1).Interior.ColorIndex = xlNone
        .Offset(1).Font.Bold = False
        For i = 2 To .Rows.Count
            x = Application.Match(.Cells(i, "a").Value, Sheets("Sheet2").Columns("A"), 0)
            If IsNumeric(x) Then
                With .Rows(i)
                    .Interior.Color = vbYellow
                    .Font.Bold = True

                End With
            End If
        Next
    End With

    
End Sub

Can you help me modify the code so it will loop and apply the same action to other columns in Sheet1?
I have many columns on my actual sheet (around 400) but for the purpose of demo, I have only added 5 columns on my example spreadsheet.
Sheet2 will not change, I only have 1 Column in this sheet (Only Column1)
I hope you can help me out. Thank you in advance.

Option Explicit

Sub Flag()
    Dim i As Long, ii As Long, x
    Application.ScreenUpdating = False
    With Sheets("Sheet1").[B5].CurrentRegion
        .Offset(1).Interior.ColorIndex = xlNone
        .Offset(1).Font.Bold = False
        For ii = 1 To .Columns.Count
            For i = 2 To .Rows.Count
                x = Application.Match(.Cells(i, ii).Value, Sheets("Sheet2").Columns("A"), 0)
                If IsNumeric(x) Then
                    With .Cells(i, ii)
                        .Interior.Color = vbYellow
                        .Font.Bold = True
                     End With
                End If
        Next i
    Next ii
    End With
    Application.ScreenUpdating = True
End Sub

..............................................
Thanks.gif