Validation riddle with VBA

The intent here is simple. On sheet1, Column A1-A100, each cell is allowed a certain entry as determined by a list in B1-B6. Very simple.

Here is the VBA code that works.

sub test()
dim rlist as string
rList = "$B$1:$B$6"

With Range("A1:A100")
    With .Validation
        .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
        xlBetween, Formula1:="=" & rList
    End With
End With
End Sub

If I add the following variable
secstr = "$B$6" and substitute the following for rlist:

rlist=Chr(34) & "$B$1:" & secstr & Chr(34), it results in rlist being exactly "$B$1:$B$6" as before, but the procedure fails, the dreaded Run time error 1004 that hangs on the 2 lines starting with .ADD.

Here is the modified code.

sub test()
dim rlist as string
dim secstr as string

secstr="$B$6"
rlist=Chr(34) & "$B$1:" & secstr & Chr(34)

With Range("A1:A100")
With .Validation
.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
xlBetween, Formula1:="=" & rList
End With
End With

End Sub

Any ideas?

Sub test()
Dim secstr As String, rlist As String

secstr = "$B$6"
rlist = "$B$1:" & secstr

With Range("A1:A100")
    With .Validation
        .Delete
        .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
            xlBetween, Formula1:="=" & rlist
    End With
End With

End Sub

In

rList = "$B$1:$B$6"

The quote marks are not part of the string, they are there to tell the compiler where the string starts and stops.

In

secstr="$B$6"
rlist=Chr(34) & "$B$1:" & secstr & Chr(34)

The Chr(34) (quote marks) are part of the string.

That's why they act differently when used in list definition

Run this test program to see the difference

Dim rList1 as String, rList2 as String, secstr as String

rList1 = "$B$1:$B$6"

secstr ="$B$6"
rlist2 = Chr(34) & "$B$1:" & secstr & Chr(34)

Msgbox rList1 & vbcr & rList2