Drag and drop text in one click

If the value is in the active cell ...

Sub CopyAndDrop()
    ActiveCell.Copy Application.InputBox("Paste where?", , , , , , , 8)
End Sub

Sub CopyDropAndDeleteOriginal()
    Dim cel As Range: Set cel = ActiveCell
    cel.Copy Application.InputBox("Paste where?", , , , , , , 8)
    cel.ClearContents
End Sub

Attach a shortcut to whichever macro does what you need

The input box allows the user to type in the destination cell address or to click on that cell

two options using event macros

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
    If Not Intersect(Range("A2:A1000"), Target) Is Nothing Then
        Cancel = True
        Target.Copy Application.InputBox("Paste where?", , , , , , , 8)
    End If
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.CountLarge > 1 Then Exit Sub
    If Not Intersect(Range("A2:A1000"), Target) Is Nothing Then Target.Copy Application.InputBox("Paste where?", , , , , , , 8)
End Sub

Another option
- click in range A2 to A1000 and copy that value to any cell clicked (here in range J2 to J1000)

'declare variables at TOP of sheet module above all procedures

Private Cel As Range, Drag As Boolean


Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.CountLarge > 1 Then Exit Sub
'copy from here
    If Not Intersect(Range("A2:A1000"), Target) Is Nothing Then
        Set Cel = Target
        Drag = True
    End If
'paste here
    If Not Intersect(Range("J2:J1000"), Target) Is Nothing Then
        If Drag = True And Not Cel Is Nothing Then
            Cel.Copy Target
            Set Cel = Nothing
            Drag = False
        End If
    End If
End Sub