Data Logging?

[Rick-O-Shay]

Hello,

I have a worksheet with a script that will go out and fetch interest rates from a website. Someone pulls this data once every day and it works great. Is there a way to create a new worksheet where I can have data from a cell logged? For example if cell C4 has an interest rate it would get logged in a separate worksheet in A1. The next day when the rates are imported, the new value would automatically get saved to A2, so on and so forth to keep a log and we can historically look at all the rates?

[bakerman2]

Is there a way to create a new worksheet where I can have data from a cell logged?

Yes there is. Post a small example file to show your layout and a result sheet showing the desired outcome.

[Rick-O-Shay]

Hi,

Thanks for helping me. Attached is a file that will get rates, and I make a results worksheet with the desired outcome.

Thank you!

[bakerman2]

Let's start with this one.

Sub tst()
    Dim mydate As Date, sh As Worksheet
    Set sh = Sheets("Libor Interest Rates")
    
    With CreateObject("VBScript.RegExp")
        .Pattern = "\d{1,2}\/\d{1,2}\/\d{2,4}"
        mydate = .Execute(sh.Range("A12").Value).Item(0).Value
    End With
    
    With Sheets("Results Tab")
        If Not IsError(Application.Match(CDbl(mydate), .Columns(1), 0)) Then Exit Sub
        .Range("A" & .Rows.Count).End(xlUp).Offset(1) = mydate
        .Range("B" & .Rows.Count).End(xlUp).Offset(1) = sh.Range("C6").Value
        .Range("C" & .Rows.Count).End(xlUp).Offset(1) = mydate
        .Range("D" & .Rows.Count).End(xlUp).Offset(1) = sh.Range("C10").Value
    End With
End Sub

[Rick-O-Shay]

Exactly what I was looking for. Thanks so much man!