Using string variables to call another macro

First: This copies the sheet directly as a seperate workbook and formats it there. Only has to copy the sheet once.

'-----------Gets AgentCallSummaryReport-----------------
Sub CopyACSReport()
    
    Application.ScreenUpdating = False
    
    With Workbooks.Open("C:\Users\chs103233\Documents\reports\DeerFoot\ACS Sample Report.xlsb")
        .Sheets("Sheet1").Copy  'copy sheet as a new workbook
        .Close SaveChanges:=False
    End With
    
    '------------------Calls Sub to Format the Agent Call Summary Report----------------------------
    Call formatACS 'Process the Active sheet. the one that was just copied
    
    '----------Saves the Active Workbook inside the appropriate folder ---------------
    ActiveWorkbook.SaveAs "C:\Users\chs103233\Documents\reports\DeerFoot mail\AgentCallSummaryReport.xlsx"
    ActiveWorkbook.Close
    
    Application.ScreenUpdating = True
    
    '---------message box saying that job is complete ---------------
    MsgBox "AgentCallSummaryReport has been processed", vbInformation, ""
    
End Sub

Secondly: Assigning variables seems overly complex and unnecessary. Just duplicate the above procedure for the other buttons and change the filename, formatting macro, save name, and message box. There's not much else going on in the procedure.

The ACSReport sub passes strings to the ProcessReport procedure. I think it's self explanatory.

Sub ACSReport()
    ProcessReport "C:\Users\chs103233\Documents\reports\DeerFoot\", "ACS Sample Report.xlsb", _
                  "C:\Users\chs103233\Documents\reports\DeerFoot mail\", "AgentCallSummaryReport.xlsx", _
                   "formatACS", "Agent Call Summary Report has been processed."
End Sub

'-----------Process Reports-----------------
Sub ProcessReport(strPath As String, strFile As String, _
                  strSavePath As String, strSaveFile As String, _
                  strFormat As String, strMsg As String)
    
    Application.ScreenUpdating = False
    
    With Workbooks.Open(strPath & strFile)
        .Sheets(1).Copy  'copy sheet as a new workbook
        .Close SaveChanges:=False
    End With
    
    '------------------Calls Sub to Format the Report----------------------------
    Application.Run strFormat 'Process the Active sheet; the one that was just copied
    
    '----------Saves the Active Workbook inside the appropriate folder ---------------
    ActiveWorkbook.SaveAs strSavePath & strSaveFile
    ActiveWorkbook.Close
    
    Application.ScreenUpdating = True
    
    '---------message box saying that job is complete ---------------
    MsgBox strMsg, vbInformation, ""
    
End Sub