Class module for userform textboxes

Sorry, I was wrong,misunderstand the question.

You need to post example file as your current code is not clear on how it is used.
On the surface it looks like you are multiplying the contents of a textbox by the contents of another textbox. But as you are doing this in the change event everytime you update the textbox it will trigger the change event again and carry on in a loop.

Your class would need to include 2 textbox objects.

Userform module

Private mInputs As Collection
Private Sub UserForm_Initialize()

    Dim index As Long
    Dim inputCtl As Class1
    
    Set mInputs = New Collection
    For index = 1 To 3
        Set inputCtl = New Class1
        Set inputCtl.Price = Me.Controls("TextBox" & index & "p")
        Set inputCtl.Number = Me.Controls("TextBox" & index & "n")
        Set inputCtl.Total = Me.Controls("TextBox" & index & "t")

        mInputs.Add inputCtl, CStr(mInputs.Count + 1)
    Next
    
End Sub


Private Sub UserForm_Terminate()

    Do While mInputs.Count > 0
        mInputs.Remove mInputs.Count
    Loop
    Set mInputs = Nothing
    
End Sub

Class module, Class1

Option Explicit

Public WithEvents Number As MSForms.TextBox
Public Price As MSForms.TextBox
Public Total As MSForms.TextBox

Private Sub Class_Terminate()

    Set Number = Nothing
    Set Total = Nothing
    Set Price = Nothing
    
End Sub


Private Sub Number_Change()
    Dim result As Variant
    
    result = "0"
    On Error Resume Next
    
    result = Val(Price.Text) * Val(Number.Text)
    Total.Text = result
    
    Exit Sub
End Sub

Hi, I have a next question.
What would be te cllas module solution if I want the total of the 3 TextBoxt textboxes.
Thanks to look into my problem.

You could have added a public sub to the userform and used that.
But I have used another class object to centralise the callbacks to the userform.


Class module, CEventListener

Option Explicit

Public Event TotalChange()
Public Sub Total_Change()
    RaiseEvent TotalChange
End Sub

revised Class1 module code

Option Explicit
Public WithEvents Number As MSForms.TextBox
Public Price As MSForms.TextBox
Public total As MSForms.TextBox
Public WithEvents Listener As CEventListener

Private Sub Class_Terminate()
    Set Number = Nothing
    Set total = Nothing
    Set Price = Nothing
    Set Listener = Nothing
End Sub

Private Sub Number_Change()
    Dim result As Variant
    result = "0"
    On Error Resume Next
    result = Val(Price.Text) * Val(Number.Text)
    total.Text = result
    
    Me.Listener.Total_Change
    
    Exit Sub
End Sub

revised userform code

Private mInputs As Collection
Private WithEvents mEventListener As CEventListener

Private Sub mEventListener_TotalChange()

    Dim index As Long
    Dim total As Double
    
    For index = 1 To 3
        total = total + Val(Me.Controls("TextBox" & index & "t").Text)
    Next
    Me.TextBox4.Text = total
    
End Sub
Private Sub UserForm_Initialize()
Dim index As Long
Dim inputCtl As Class1

    Set mEventListener = New CEventListener
    
    Set mInputs = New Collection
    For index = 1 To 3
        Set inputCtl = New Class1
        Set inputCtl.Price = Me.Controls("TextBox" & index & "p")
        Set inputCtl.Number = Me.Controls("TextBox" & index & "n")
        Set inputCtl.total = Me.Controls("TextBox" & index & "t")
        Set inputCtl.Listener = mEventListener
    mInputs.Add inputCtl, CStr(mInputs.Count + 1)
    Next
End Sub
Private Sub UserForm_Terminate()
    Do While mInputs.Count > 0
        mInputs.Remove mInputs.Count
    Loop
    Set mInputs = Nothing
    Set mEventListener = nothing
End Sub

If the issue is with numeric separators and decimal delimiter, then it would not have been working for you at the start.

I assume for you the number ten you would use comma for decimal 10,0 rather than the period I would expect with UK settings 10.0

What does the VAL function return for the test values? You will need to step through the code and check or use debug.print commands to write to the immediate window