Copy data from file to existing file to corresponding row and Column

Working on project where one component of calculations requires:

1. When clicking some button to offer dialog windows asking which file to open
2. After choosing file: open the file
3. Copy data from Predefined sheet (in this case Summary sheet) from area with data (from Grey Cells (here starting point is always same Cell- E5, but the last raw and column should be found using may be raw count and column count?)
4. Paste in opened workbook (in the Summary sheet) in Grey area (based on column and raw values


The case is that the columns might be added, items also might be changed current file vs old, therefore the direct copy paste will not work and the copy of grey area should be match with column and raw values.


attaching the sample file for Copying the data and for pasting the data.

Place this macro in the "Copying" file.

Sub CopyData()
    Application.ScreenUpdating = False
    Dim flder As FileDialog, FileName As String, FileChosen As Integer, wkbSource As Workbook, wsSource As Worksheet, wsDest As Worksheet
    Dim LastRow As Long, lCol As Long, x As Long, itm As Range, store As String, fnd As Range, Val As String, i As Long, v1
    x = 4
    Set wsSource = ThisWorkbook.Sheets("Summary")
    LastRow = wsSource.Cells.Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
    lCol = wsSource.Cells(3, Columns.Count).End(xlToLeft).Column
    v1 = wsSource.Range("B3", wsSource.Range("B" & Rows.Count).End(xlUp)).Resize(, lCol - 1).Value
    Set flder = Application.FileDialog(msoFileDialogFilePicker)
    flder.Title = "Please Select a file."
    FileChosen = flder.Show
    FileName = flder.SelectedItems(1)
    Set wkbSource = Workbooks.Open(FileName)
    Set wsDest = Sheets("Summary")
    For i = 3 To UBound(v1, 1)
        Val = v1(i, 1)
        Set itm = wsDest.Range("B:B").Find(Val, LookIn:=xlValues, lookat:=xlWhole)
        If Not itm Is Nothing Then
            For x = 4 To lCol - 1
                store = v1(1, x)
                Set fnd = wsDest.Rows(3).Find(store, LookIn:=xlValues, lookat:=xlWhole)
                If Not fnd Is Nothing Then
                    With wsDest
                        .Cells(itm.Row, fnd.Column) = wsSource.Cells(i + 2, x + 1)
                    End With
                End If
            Next x
        End If
    Next i
    Application.ScreenUpdating = True
End Sub

You are very welcome.