How to move rows based on cell value to multiple tabs?

Hi everyone I have the macro below that works well. I just need to expand on it and need some guidance.

It currently moves data found in sheet 1 to sheet 2 if the values in column F = "Y". First, I would like the formulas on columns F:I to be copied to the last cell with data. Then, I need more conditions, for example if any cell in column "G" = No Issues Found, move to sheet 3, if cells in column "H" = Review then move to sheet 4 and if the cell in column "I" equals "Test Fail" then move to sheet5.

Biggest issue I'm thinking is that some rows MIGHT need to be in multiple tabs but everything I found in Google deletes the row once it meets the first criteria.

Sub MoveData()

    Dim xRg As Range
    Dim xCell As Range
    Dim I As Long
    Dim J As Long
    Dim K As Long
    Dim L As Long
    
    I = Worksheets("Sheet1").UsedRange.Rows.count
    J = Worksheets("Sheet2").UsedRange.Rows.count
    If J = 1 Then
       If Application.WorksheetFunction.CountA(Worksheets("Sheet2").UsedRange) = 0 Then J = 0
    End If
    Set xRg = Worksheets("Sheet1").Range("F1:F" & I)
    On Error Resume Next
    Application.ScreenUpdating = False
    For K = 1 To xRg.count
        If CStr(xRg(K).Value) = "Y" Then
            xRg(K).EntireRow.Copy Destination:=Worksheets("Sheet2").Range("A" & J + 2)
            xRg(K).EntireRow.Delete
            If CStr(xRg(K).Value) = "Y" Then
                K = K - 1
            End If
            J = J + 1
        End If
    Next
    Application.ScreenUpdating = True
End Sub

Hi AccountingJ...
As an example...See attached file...

Sub sintek()
Dim Crit, i As Long
Crit = Array("Y", "No Issues Found", "Review", "Test Fail")
With Sheets("Data")
    .Range("G2:I2").Copy .Range("G3").Resize(.Cells(.Rows.Count, 1).End(xlUp).Row - 2)
    For i = LBound(Crit) To UBound(Crit)
        With .Cells(1).CurrentRegion
            .AutoFilter i + 6, Crit(i)
            .SpecialCells(12).Copy Sheets(Crit(i)).Range("A1")
            .AutoFilter
        End With
    Next i
End With
End Sub

Sub sintek()
Dim Crit, i As Long
Crit = Array("Y", "No Issues Found", "Review", "Test Fail")
With Sheet1
    .Range("G2:I2").Copy .Range("G3").Resize(.Cells(.Rows.Count, 1).End(xlUp).Row - 2)
    For i = LBound(Crit) To UBound(Crit)
        With .Cells(1).CurrentRegion
            .AutoFilter i + 6, Crit(i)
            .SpecialCells(12).Copy Sheets(i + 2).Range("A1")
            .AutoFilter
        End With
    Next i
End With
End Sub

Thanks for rep by the way...

I had to add more columns and pushed back the formulas back to range T2:AA2 and also added some tabs.

I made the changes to your macro, see below:

Sub sintek()
Dim Crit, i As Long
Crit = Array("Y", "No Issues Found", "Review", "Test Fail", "Test Again", "N", "Audit Issue", "Review Needed")
With Sheets("Data")
    .Range("T2:AA2").Copy .Range("T3").Resize(.Cells(.Rows.Count, 1).End(xlUp).Row - 2)
    For i = LBound(Crit) To UBound(Crit)
        With .Cells(1).CurrentRegion
            .AutoFilter i + 6, Crit(i)
            .SpecialCells(12).Copy Sheets(Crit(i)).Range("A1")
            .AutoFilter
        End With
    Next i
End With
End Sub

The macro runs but does not transfer over the data like it did before, what other changes do I need to do to it?

The macro runs but does not transfer over the data like it did before, what other changes do I need to do to it?

Will only be able to ascertain issue once I see the file...

Sub sintek()
Dim Crit, i As Long
Crit = Array("Y", "No Issues Found", "Review", "Test Fail", "Test Again", "Audit Issue", "N", "Review Needed") ' ! Keep in order of appearance in Col
With Sheets("Data")
    .Range("T2:AA2").Copy .Range("T3").Resize(.Cells(.Rows.Count, 1).End(xlUp).Row - 2)
    For i = LBound(Crit) To UBound(Crit)
        With .Cells(1).CurrentRegion
            .AutoFilter i + 20, Crit(i)
            .SpecialCells(12).Copy Sheets(Crit(i)).Range("A1")
            .AutoFilter
        End With
    Next i
End With
End Sub

Changes in red...

Crit = Array("Y", "No Issues Found", "Review", "Test Fail", "Test Again", "Audit Issue", "N", "Review Needed") ' ! Keep in order of appearance in Col

.AutoFilter i + 20, Crit(i) '! i starts at 0 so i + 20 is Col Number 20 to filter first Crit i.e "Y" and so on...

pleasure...