Filter by multiple criteria

[scrabtree23]

See attached file.

I’d like to add VBA to automatically filter a table (see attached example).
I want to filter and keep everything in the table where the value in Column D equals Blue, Black, or Red.
I also want the filter to then keep anything in Column B where the value is equal to any text string or is less than or equal to the date in cell K1.

[jindon]

I don't think AutoFilter can do...
AdvancedFilter.

Sub test()
    Dim r As Range
    With Sheets("sheet1").Cells(1).CurrentRegion
        Set r = .Offset(, .Columns.Count + 1).Range("a1:a2")
        r(2).Formula = "=or(b2=k$1,or(d2={""blue"",""black"",""red""}))"
        .AdvancedFilter 1, r
        r(2) = Empty
    End With
End Sub

[scrabtree23]

I tested it. Thanks, by the way. It seemed to do fine for Column D, but it didn't do the next filter on Column B

[Bo_Ry]

Please try

Sub filt()
With Cells(1).CurrentRegion
    .AutoFilter
    .AutoFilter Field:=4, Criteria1:=Array("Blue", "Black", "Red"), Operator:=xlFilterValues
    .AutoFilter Field:=2, Criteria1:="=*", Operator:=xlOr, Criteria2:="<=" & [K1]
End With
End Sub

[jindon]

I also want the filter to then keep anything in Column B where the value is equal to any text string or is less than or equal to the date in cell K1.

Missed

Sub test()
    Dim r As Range
    With Sheets("sheet1").Cells(1).CurrentRegion
        Set r = .Offset(, .Columns.Count + 1).Range("a1:a2")
        r(2).Formula = "=or(and(b2<>"""",or(istext(b2),b2<=k$1)),or(d2={""blue"",""black"",""red""}))"
        .AdvancedFilter 1, r
        r(2) = Empty
    End With
End Sub

[Sintek]

Sub sintekJ3v16()
With Cells(1).CurrentRegion
    .AutoFilter 2, "*", xlOr, "<=" & CDbl(Range("K1")) & ""
    .AutoFilter 4, Array("Blue", "Black", "Red"), xlFilterValues
End With
End Sub

[Bo_Ry]

@sintek
Thanks for the CDbl tip

I'm quite a newbie for VBA.
Why do we convert the Date to double?

To prevent m/d/y d/m/y conflict ?

[Sintek]

Dates are stored as numbers...Cdbl() changes to double for filter conversion...
Can make use of Clng() or Cdate() in some cases...