Correct syntax for replace command

Here is the code

Sub ViewShortage()
Dim shtS As Worksheet       ' Shortage Report Worksheet
Dim shtP As Worksheet       ' Pivot Table Worksheet
Dim shtC As Worksheet       ' Current Workbench
Dim PartNum As String       ' Part Number

' intialize variables
Set shtS = Sheets("Shortage Report")
Set shtP = Sheets("Shortage Pivot")
Set shtC = Sheets("Current Workbench")

Application.ScreenUpdating = False
Application.Calculation = xlManual

If Intersect(Selection, shtC.Range("Table_Current_Workbench")) Is Nothing Then
    MsgBox "Please select a cell in the table", vbOKOnly, "Select Part Number"
    Exit Sub
End If

PartNum = shtC.Cells(Selection.Row, "A")
Range("Sel_Part") = PartNum
If Range("Short_Count") = 0 Then
    MsgBox "This part is not on the shortage report", vbOKOnly, "Part Not Found"
    Exit Sub
End If

' Clear Table and copy the pivot information
ClearTable shtS, "Table_Shortage_Report"
Application.ScreenUpdating = True

Range("Short_Pivot_Copy").Copy
    shtS.Range("A4").PasteSpecial xlPasteValues

range("Table_Shortage_Report").Replace("(blank)","")
shts.Range ("Table_Shortage_Report").Replace(what:="(balnk)", replacement:="", lookat:= xlwhole, Matchcase:=false))

Application.Calculation = xlAutomatic
End Sub

I get a syntax error on both of the attempted Replace commands. What is the correct syntax?

Never mind, I got it I have to make a dummy Boolean value to assign the return to.

RTN = Range("Table_Shortage_Report").Replace("(blank)","")

Where RTN is defined as Boolean/

Originally Posted by dflak

Range("Table_Shortage_Report").Replace("(blank)","")

Actually, your problem is with your use of parentheses. This would work fine...

Range("Table_Shortage_Report").Replace "(blank)", ""

but when you surrounded the arguments in parentheses, VBA attempted to do what it always does with parentheses that are not required by syntax... it attempted to evaluate the contents of the parentheses in order to produce a single value. For subroutines and methods (Replace is a method), parentheses are not required for by syntax. If there is just a single argument, surrounding it with parentheses is not a problem (a value evaluates to itself); however, when there is two or more arguments, surrounding them with parentheses asks VBA to create a single evaluated value from them... that can't be done because, well, there are two or more independent values and VBA can't evaluate them into a single value so it raises an error instead. By the way, your solution method worked because you used Replace as a function (which it is designed to act as if desired) and functions require parentheses around its argument list by syntax.