Stock adjustment Data in excel

Hi

I have 3 following datas in the columns
1) Opening Balance
2) Product Sold
3) Closing Balance (Difference between Opening balance - Products Sold)

In the attached excel sheet some of the closing balance is showing as negative (Minus).

If the Closing balance is less than zero like (-1,-2,-3 etc) then the Product sold column to be changed like decrease 1 number (-1) till the closing balance come to zero.
For example in the first case the Product Name apple Opening balance is 100 and unit sold is 105. The closing balance is showing as -5
Now the units sold be changed to 100. Now i doing manually till the closing balance get zero.
This should do only if the closing balance is negative balance.
I need this in macro because i have many of products using loop based on the available data in the sheet.

Try:

Sub AAA()
    Dim vData       As Variant
    Dim i           As Long

    With ActiveSheet.Range("A1").CurrentRegion
        With .Offset(1).Resize(.Rows.Count - 1).Columns("B:C").Cells
            vData = .Value

            For i = 1 To UBound(vData)
                If vData(i, 2) > vData(i, 1) Then
                    vData(i, 2) = vData(i, 1)
                End If
            Next i

            .Value = vData
        End With
    End With

End Sub

Artik

Thanks working

can you explain about this line

vData = .Value

ActiveSheet.Range("A1").CurrentRegion is the range A1:D5.
.Offset(1).Resize(.Rows.Count - 1).Columns("B:C").Cells is the range A1:D5 shifted down one row and minus one row, so you get the range A2:D5. And in this area, we are interested in the data from columns B:C.
vData = .Value is to get the data from the range B2:C5 to the vData variable.

Artik

Thanks for the clarification.
I need additional one column in the E Column. The difference value to be shown in the E column (Next to Closing Balance)

For example in the first case the Product Name apple Opening balance is 100 and unit sold is 105. The closing balance is showing as -5
The same Difference value 5 to be shown in the E2 Column.

Sub BBB()
    Dim vData       As Variant
    Dim vResultE As Variant
    Dim i           As Long

    With ActiveSheet.Range("A1").CurrentRegion
        With .Offset(1).Resize(.Rows.Count - 1).Columns("B:C").Cells
            vData = .Value
            
            ReDim vResultE(1 To UBound(vData), 1 To 1)

            For i = 1 To UBound(vData)
                vResultE(i, 1) = vData(i, 2) - vData(i, 1)
                
                If vData(i, 2) > vData(i, 1) Then
                    vData(i, 2) = vData(i, 1)
                End If
            Next i

            .Value = vData
            .Offset(, 3).Resize(, 1).Value = vResultE
        End With
    End With

End Sub

Artik