Column width based on Heading Value

Assume there were 8 columns. s is array of 8 width.

PHP Code: 

Option Explicit
Sub test()
Dim s, i&
s = Array(20, 8, 10, 11, 12, 13, 14, 15) ' assume there were 8 widths of 8 columns
    For i = 0 To UBound(s) - 1
        Cells(1, i + 1).ColumnWidth = s(i)
    Next
End Sub 


If this does not work then only way is to see sample sheet...
Assumes headers in Row 8 and they exist in Array
Add as many headers as required...Change red numbers to header column width requirement...

Sub J3v16()
Dim Hdr, Chk, i As Long
Hdr = [{"Category",20,"Emp Code",8, "Employee Name",10,"Beneficiary Name",25}]
For i = 1 To Cells(8, Columns.Count).End(xlToLeft).Column
    Chk = Application.Match(Cells(8, i), Hdr, 0)
    Columns(i).ColumnWidth = Hdr(Chk + 1)
Next i
End Sub

That's obvious...
See post 4
Assumes headers in Row 8 and they exist in Array

Add as many headers as required...Change red numbers to header column width requirement...

You did not follow instructions...
Where is other Headers and their corresponding required column widths...
Bank Account Number SWIFT Code Country Code Net - USD Net - SAR

The following macro will only widen defined columns. If other columns appear, their width will not be changed.

Sub AdjustColumnWidth()
  Dim varrHeaders As Variant
  Dim varrColsWidth As Variant
  Dim lColIdx As Long
  Dim i As Long
  
  varrHeaders = Split("Category,Emp Code,Employee Name,Beneficiary Name,Bank Account Number,SWIFT Code,Country Code,Net - USD,Net - SAR", ",")
  'Examples of column widths:
  'Category,Emp Code,Employee Name,Beneficiary Name,Bank Account Number,SWIFT Code,Country Code,Net - USD,Net - SAR
  '   20       8          25              25            30                  15          5           12        12
  varrColsWidth = Array(20, 8, 25, 25, 30, 15, 5, 12, 12)
  
  On Error Resume Next
  For i = 0 To UBound(varrHeaders)
    lColIdx = 0
    lColIdx = FindColumnInRange(varrHeaders(i), Rows(8))
    Columns(lColIdx).ColumnWidth = varrColsWidth(i)
  Next i
  
End Sub


Function FindColumnInRange(ByVal columnName As String, ByRef source As Range) As Long
    Dim rngHeaderData As Range
    Dim rngFind     As Range

    Set rngHeaderData = source.Resize(1)

    Set rngFind = rngHeaderData.Find(What:=columnName, After:=rngHeaderData.Cells(rngHeaderData.Count), _
                                     LookIn:=xlValues, LookAt:=xlWhole, _
                                     SearchOrder:=xlByRows, SearchDirection:=xlNext, _
                                     MatchCase:=False, SearchFormat:=False)

    If Not rngFind Is Nothing Then
        FindColumnInRange = rngFind.Column
    Else
        Err.Raise 11110, , "Can't find column """ & columnName & """  in source "
    End If

End Function

Artik

Add like this...By the way your Net Headers have leading spaces...

Sub J3v16()
Dim Hdr, Chk, i As Long
Hdr = [{"Category",20,"Emp Code",8, "Employee Name",10,"Beneficiary Name",25,"Bank Account Number",30,"SWIFT Code",5,"Country Code",12,"Net - USD",50,"Net - SAR",21}]
For i = 1 To Cells(8, Columns.Count).End(xlToLeft).Column
    Chk = Application.Match(Cells(8, i), Hdr, 0)
    Columns(i).ColumnWidth = Hdr(Chk + 1)
Next i
End Sub

Glad I could contribute...Tx for rep +

As per Artik ...

If other columns appear, their width will not be changed.

Code amendment...

If Not IsError(Chk) Then Columns(i).ColumnWidth = Hdr(Chk + 1)