how to call for printer function

I have a printer, and finally figured out that it changes on the name, so its named like this:

Canon on NE01:
Canon on NE02:
Canon on NE04:
Canon on NE05:
and so forth
after searching it came up to something that works on dynamic names of printers from this link: https://www.excelforum.com/excel-pro...numbering.html

If someone that can help me write the sub to print on whatever the printer name is to print the below sheets:

Sheet4.PrintOut

i dont know how to call for functions, and just started reading about functions, unsure how to use it yet. If someone would kindly moc up a simple example of this please
Arkadi in post #30 on that link, if someone that can merged it to print out sheet4 please

That function will work
Put it in a standard module.

'Written: November 28, 2009
'Author:  Leith Ross
'Summary: Finds a printer by name and returns the printer name and port number.

Function FindPrinter(ByVal PrinterName As String) As String

 'This works with Windows 2000 and up
 
  Dim Arr As Variant
  Dim Device As Variant
  Dim Devices As Variant
  Dim Printer As String
  Dim RegObj As Object
  Dim RegValue As String
  Const HKEY_CURRENT_USER = &H80000001
       
    Set RegObj = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
    RegObj.enumvalues HKEY_CURRENT_USER, "Software\Microsoft\Windows NT\CurrentVersion\Devices", Devices, Arr
    
      For Each Device In Devices
        RegObj.getstringvalue HKEY_CURRENT_USER, "Software\Microsoft\Windows NT\CurrentVersion\Devices", Device, RegValue
        Printer = Device & " on " & Split(RegValue, ",")(1)
        If InStr(1, Printer, PrinterName, vbTextCompare) > 0 Then
           FindPrinter = Printer
           Exit Function
        End If
      Next
      
      
End Function

Then call it from your print routine, e.g.
I've highlighted the function line. Replace "Microsoft Print to PDF" with the full name of your printer as displayed in file/print

Sub ToPrint()
Dim CurrPrinter As String
Dim SetPrinter As String

CurrPrinter = ActivePrinter 'remember the current printer

SetPrinter = FindPrinter("Microsoft Print to PDF")  'call the function on the printer
If Len(SetPrinter) Then
    ActivePrinter = SetPrinter 'if no error, change the active printer
    Sheet4.PrintOut 'perform the print
    ActivePrinter = CurrPrinter 'change the active printer back to what it was before
End If
End Sub

thank you Bytemarks for the reply, its sending to the wrong printer, the Printer name changes depeding on which computer, the name of the printer is "Canon on NE01:" "Canon on NE02:", "Canon on NE03" and so forth, depeding on the computer that the macro runs, so can the code in that link from arkadi post #30 be linked to Leith Ross code can be call to search for the printer name and call for it?
i want tocall for this function before it prints :

'by arkadi in post #30 on the link posted
Public Function prnfull(prnname As String) As String

Dim prnport, strsetting As String
strsetting = CreateObject("WScript.Shell").RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\Devices\" & prnname)
prnport = Split(strsetting, ",")
prnfull = prnname & " on " & prnport(1)

End Function