VBA code to run when linked cell value changes

I have created several worksheets with VBA code that hide columns that are not referenced in a drop down list of months. The sheets work as intended when the drop down list changed manually in each worksheet. Using VBA in the workbook module, I have synchronized the dropdowns in each sheet to mimic each other and I would like the macros in each sheet to run when any one dropdown selection has been changed. My code is below:

Private Sub Worksheet_Change(ByVal target As Range)

If target.Address = "$B$3" Then

ActiveSheet.Unprotect

Application.ScreenUpdating = False
Application.EnableEvents = False

StartColumn = 17
LastColumn = 112
iRow = 1
For i = StartColumn To LastColumn
If Cells(iRow, i).Value <> "X" Then
Cells(iRow, i).EntireColumn.Hidden = False
Else
Cells(iRow, i).EntireColumn.Hidden = True
End If
Next i

Application.ScreenUpdating = True
Application.EnableEvents = True

ActiveSheet.Protect

End If

End Sub

This macro only work's when the dropdown in this worksheet's cell B3 is changed manually.
I have tried to change "If target.Address = "$B$3" Then" to "If Not Intersect (Target, Me.Range("B3")) Is Nothing Then" which isn't working.
I have also tried to change the Worksheet_Change to Worksheet_Calculate and change "If target.Address = "$B$3" to

Private Sub Worksheet_Calculate()

Dim target As Range
Set target = Range("B3")

If Not Intersect(target, Range("B3")) Is Nothing Then

which is also not working. Any help would be appreciated. Thanks in advance

Pls try this code

Private Sub Worksheet_Calculate()
    Dim target As Range
    Set target = Range("B3")    
    If Not Intersect(target, Range("B3")) Is Nothing Then
        Application.EnableEvents = False
        Call HideColumnsBasedOnDropdownValue
        Application.EnableEvents = True
    End If
End Sub

Sub HideColumnsBasedOnDropdownValue()
    ActiveSheet.Unprotect
    Application.ScreenUpdating = False
    Application.EnableEvents = False    
    StartColumn = 17
    LastColumn = 112
    iRow = 1
    For i = StartColumn To LastColumn
        If Cells(iRow, i).Value <> "X" Then
            Cells(iRow, i).EntireColumn.Hidden = False
        Else
            Cells(iRow, i).EntireColumn.Hidden = True
        End If
    Next i    
    Application.ScreenUpdating = True
    ActiveSheet.Protect
End Sub

Thank you. This worked for a minute but kind of randomly, I got the error message "Unable to set the Hidden property of the Range class" and the row "Cells(iRow, i).EntireColumn.Hidden = True" was highlighted. Any thoughts?

I have created several worksheets with VBA code that hide columns that are not referenced in a drop down list of months.

Try a workbook level change event.

Private Sub Workbook_SheetChange(ByVal sh As Object, ByVal Target As Range)
Dim sWorkSheets$, StartColumn&, LastColumn&, iRow&, sHts, ws As Worksheet, s%, i&
sWorkSheets$ = "Sheet1,Sheet2,Sheet3"
StartColumn = 1
LastColumn = 13
iRow = 1

If Target.Address = "$B$3" And InStr(sWorkSheets, sh.Name) > 0 Then
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    sHts = Split(sWorkSheets, ",")
    For s = 0 To UBound(sHts)
        Set ws = Nothing
        On Error Resume Next
        Set ws = Sheets(sHts(s))
        On Error GoTo 0
        If Not ws Is Nothing Then
            ws.Unprotect
            For i = StartColumn To LastColumn
                With ws.Cells(iRow, i)
                    .EntireColumn.Hidden = .Value = "X"
                End With
            Next i
              ws.Protect
        End If
    Next
End If
Application.ScreenUpdating = True
Application.EnableEvents = True
End Sub

Thank you ByteMarks. I already have some code in the workbook module (below). I'm not sure how to combine what you provided above with what's already there. I'm also having some trouble understanding what items are changable variables in your code. I assume column #s and Sheet names?

Private Sub Workbook_SheetChange(ByVal sh As Object, ByVal Target As Range)
On Error GoTo ErrorOut
Application.EnableEvents = False
With ThisWorkbook
Select Case sh.Name
Case "Financial Graphs"
.Sheets("Cost Code Chg").Range("B23") = .Sheets("Financial Graphs").Range("O3")
.Sheets("Monthly Financial Input").Range("E2") = .Sheets("Cost Code Chg").Range("B23")
.Sheets("Monthly Schedule Input").Range("B3") = .Sheets("Monthly Financial Input").Range("E2")
Case "Cost Code Chg"
.Sheets("Monthly Financial Input").Range("E2") = .Sheets("Cost Code Chg").Range("B23")
.Sheets("Monthly Schedule Input").Range("B3") = .Sheets("Monthly Financial Input").Range("E2")
.Sheets("Financial Graphs").Range("O3") = .Sheets("Monthly Schedule Input").Range("B3")
Case "Monthly Financial Input"
.Sheets("Monthly Schedule Input").Range("B3") = .Sheets("Monthly Financial Input").Range("E2")
.Sheets("Financial Graphs").Range("O3") = .Sheets("Monthly Schedule Input").Range("B3")
.Sheets("Cost Code Chg").Range("B23") = .Sheets("Financial Graphs").Range("O3")
Case "Monthly Schedule Input"
.Sheets("Financial Graphs").Range("O3") = .Sheets("Monthly Schedule Input").Range("B3")
.Sheets("Cost Code Chg").Range("B23") = .Sheets("Financial Graphs").Range("O3")
.Sheets("Monthly Financial Input").Range("E2") = .Sheets("Cost Code Chg").Range("B23")
End Select
End With
ErrorOut:
Application.EnableEvents = True
End Sub

pls try this code

Private Sub Workbook_SheetChange(ByVal sh As Object, ByVal Target As Range)
    On Error GoTo ErrorOut
    Application.EnableEvents = False
    With ThisWorkbook
        Select Case sh.Name
        Case "Financial Graphs"
            .Sheets("Cost Code Chg").Range("B23") = .Sheets("Financial Graphs").Range("O3")
            .Sheets("Monthly Financial Input").Range("E2") = .Sheets("Cost Code Chg").Range("B23")
            .Sheets("Monthly Schedule Input").Range("B3") = .Sheets("Monthly Financial Input").Range("E2")
        Case "Cost Code Chg"
            .Sheets("Monthly Financial Input").Range("E2") = .Sheets("Cost Code Chg").Range("B23")
            .Sheets("Monthly Schedule Input").Range("B3") = .Sheets("Monthly Financial Input").Range("E2")
            .Sheets("Financial Graphs").Range("O3") = .Sheets("Monthly Schedule Input").Range("B3")
        Case "Monthly Financial Input"
            .Sheets("Monthly Schedule Input").Range("B3") = .Sheets("Monthly Financial Input").Range("E2")
            .Sheets("Financial Graphs").Range("O3") = .Sheets("Monthly Schedule Input").Range("B3")
            .Sheets("Cost Code Chg").Range("B23") = .Sheets("Financial Graphs").Range("O3")
        Case "Monthly Schedule Input"
            .Sheets("Financial Graphs").Range("O3") = .Sheets("Monthly Schedule Input").Range("B3")
            .Sheets("Cost Code Chg").Range("B23") = .Sheets("Financial Graphs").Range("O3")
            .Sheets("Monthly Financial Input").Range("E2") = .Sheets("Cost Code Chg").Range("B23")
        End Select
    End With

    Dim sWorkSheets$, StartColumn&, LastColumn&, iRow&, sHts, ws As Worksheet, s%, i&
    sWorkSheets$ = "Sheet1,Sheet2,Sheet3"
    StartColumn = 1
    LastColumn = 13
    iRow = 1

    If Target.Address = "$B$3" And InStr(sWorkSheets, sh.Name) > 0 Then
        Application.ScreenUpdating = False
        Application.EnableEvents = False
        sHts = Split(sWorkSheets, ",")
        For s = 0 To UBound(sHts)
            Set ws = Nothing
            On Error Resume Next
            Set ws = Sheets(sHts(s))
            On Error GoTo 0
            If Not ws Is Nothing Then
                ws.Unprotect
                For i = StartColumn To LastColumn
                    With ws.Cells(iRow, i)
                        .EntireColumn.Hidden = .Value = "X"
                    End With
                Next i
                  ws.Protect
            End If
        Next
    End If
    Application.ScreenUpdating = True
    Application.EnableEvents = True
    Exit Sub
ErrorOut:
    Application.EnableEvents = True
End Sub

assume column #s and Sheet names?

s is an integer for looping through the array of worksheets called shts.
You'll probably want to change this line to match your actual worksheet names.

 sWorkSheets$ = "Sheet1,Sheet2,Sheet3"