"No more instances found"

In a macro I have this search procedure (bottom up and right to left)

Cells.Find(What:=c, After:=ActiveCell, LookIn:=xlValues, LookAt:= _
        xlPart, SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Activate

Silly, but I don't know the proper code saying "if there are no more occurrences, then...". None of those in the HELP section (Not Found, NoMatch, Is Not) seem to apply.

Thanks for your patience
ACA

2 ways
1)

On Error Resume Next
Cells.Find(What:=c, After:=ActiveCell, LookIn:=xlValues, LookAt:= _
        xlPart, SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Activate
If Err <> 0 Then
    MsgBox "Not found"
End If
On Error GoTo 0

2) use object variable

Dim r As Range
Set r = Cells.Find(What:=c, After:=ActiveCell, LookIn:=xlValues, LookAt:= _
        xlPart, SearchOrder:=xlByColumns, SearchDirection:=xlPrevious)
If r Is Nothing then
    MsgBox "Not found"
End If

Thank so very much to you both, jindon and royUK, for the immediate help.
aca

Your code, works O.K., but finding one or all occurrences at once, and then stopping, is not what I need;
sorry I didn’t express myself well.

First, in each case I enter, through an input box, the chain I'm looking for (which I call ‘c’)

Dim c As Variant
    c = InputBox(Chr(13) & " Escribe parte d lo q buscas", , , 1000, 4000)

   Cells.Find(What:=c, After:=ActiveCell, LookIn:=xlValues, LookAt:= _
        xlPart, SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Activate

But then I need for the macro to do just what a general search function does (only upwards) i.e.
Go up, PAUSE at each occurrence and, if that cell is the one I need, let me exit the search and have the cell copied etc.;
if it is not, let me click somewhere else and GO ON TO THE NEXT occurrence and pause again. And so on.
But when there are no more, let me kow also (message box “No more to be found”).

Thanks for your help, and sorry I first mistakenly posted this as a new thread.
ACA

Sub test()
Dim c, r As Range, ff As String
c = InputBox(Chr(13) & " Escribe parte d lo q buscas", , , 1000, 4000)
Set r = Cells.Find(c,,xlValues, xlPart, xlByColumns, xlPrevious)
If Not r Is Nothing Then
    ff = r.Address
    Do
        r.Activate
        If vbYes = MsgBox("Is this the one?", vbYesNo) Then exit Do
        Set r = Cells.FindPrevious(r)
    Loop Until ff = r.Address
End If
[End Sub

Thank you, jindon: works great! It's what I needed
Bless you.
ACA