Using Variables from Modules in Userforms

**googlebot** · 09-09-2008, 02:48 PM

Hello,

I was wondering if there is a good way to effectively be able to use variables in userforms, or allow them to manipulate them, without declaring them public.

I have a sub, which opens a userform, and want to be able to use variables used within the sub. To the best of my knowledge I cannot pass a variable to a userform the way you can from one sub to another.

The way I have been doing this has been simply to declare variables as public variables, but those seem to be not preferred by other programmers and I am looking for a better alternative.

Thanks,
googlebot

**Andy Pope** · 09-09-2008, 02:57 PM

You can declare variables within the userform class and reference them that way.

Code in standard code module

Sub x()

    Dim frmX As UserForm1
    
    Set frmX = New UserForm1
    
    With frmX
        .MyProperty = "Hello"
        .MyVariable = "World"
        .Show
        MsgBox .MyProperty & " " & .MyVariable
    End With
    Unload frmX
    Set frmX = Nothing
    
    
End Sub

Userform, with a single commandbutton

Public MyVariable As String

Private m_strMyProp As String
Public Property Get MyProperty() As String
    MyProperty = m_strMyProp
End Property
Public Property Let MyProperty(RHS As String)
    m_strMyProp = RHS
End Property

Private Sub CommandButton1_Click()
    Me.Hide
End Sub