Listbox non-updating/updating

**MattShoreson** · 09-15-2008, 07:25 AM

I would like to be able to change the way a listbox functions from allowing input, to not allowing input (but still being able to view previous selections).

I understand .enabled will achieve this but if it is set to false then the i am unable to scroll the list.

Any ideas/solutions?

tia Matt.

**royUK** · 09-15-2008, 07:27 AM

What kind of ListBox? On a UserForm, from the Forms ToolBar or Controls ToolBox?

**MattShoreson** · 09-15-2008, 07:30 AM

It's from the controls toolbox - the lists are placed directly on the worksheet.

(also, is there anyway of getting rid of the notice at the topas I've already read it - like an accept notice button or something along those lines?)

ta.

**royUK** · 09-15-2008, 07:42 AM

The notice is only temporary. It should go in a couple of days.

What input are you referring to, you cxan't type directly into a ListBox.

**MattShoreson** · 09-15-2008, 07:46 AM

normal listbox input - i.e. clicking an item in the listbox.

I've already created the listbox and populated it.
I want to hold the input so a user can use the current selection. (effectively non-updatable - but scrollable)
Then I want to 'switch modes' to updatable. (i.e. select more or less items (Updatable))

**royUK** · 09-15-2008, 08:09 AM

I'm not sure what you can do, you could try changing the Locked property, but how will you trigger any such change?

**Andy Pope** · 09-15-2008, 08:21 AM

Maybe this would work for you.

Userform with a listbox, commandbutton and label.
Click button to toggle 'lock' listbox selection.

You can select items when unlocked.
You can scroll list whether locked or not.

Private m_blnLocked As Boolean
Private m_vntSelected() As Variant
Private m_lngListIndex As Long

Private Sub CommandButton1_Click()

    m_blnLocked = Not m_blnLocked
    Label1.Caption = m_blnLocked
    
End Sub

Private Sub ListBox1_Change()

    If m_blnLocked Then
        m_lngListIndex = ListBox1.ListIndex
        ListBox1.Selected(ListBox1.ListIndex) = m_vntSelected(ListBox1.ListIndex)
    Else
        m_lngListIndex = ListBox1.ListIndex
        If ListBox1.ListIndex >= 0 Then
            m_vntSelected(ListBox1.ListIndex) = ListBox1.Selected(ListBox1.ListIndex)
        End If
    End If
    
End Sub

Private Sub UserForm_Initialize()

    ListBox1.List = Array(1, 2, 3, 4, 5, 6, 1, 2, 3, 4, 5, 6, 7, 8, 9)
    ListBox1.MultiSelect = fmMultiSelectMulti
    
    ReDim m_vntSelected(0 To ListBox1.ListCount - 1)
    m_blnLocked = False
    m_lngListIndex = -1
    
End Sub