Run-time error 1004 - Application-defined or object-defined error

Hi All,

This is my very first VBA project, and I'm a bit lost. I've got this run-time error:
1004 - Application-defined or object-defined error.

Could you please take a look into the program and suggest me where could the problem be?

Sub FormatTable()
Dim i As Long
Dim rng As Range
Dim celle As Range

Set rng = Range(Sheets("Sheet1").[A1], Sheets("Sheet1").[A65536].End(xlUp))


For Each celle In rng
  If IsEmpty(celle.value) and IsEmpty(celle.Offset(1, 0)) and IsEmpty(celle.Offset(2, 0)) and IsEmpty(celle.Offset(3, 0)) Then   
       celle.select
     Range("A1:H2").Select
     Selection.Copy
     Range("celle.offset(1,0)").Select
     ActiveSheet.Paste
       Range("celle.offset(-1,0)").Select
       Selection.Font.bold = True
    Range("celle.offset(5,0)").Select
    Selection.CurrentRegion.Select
    Selection.Borders(xlDiagonalDown).LineStyle = xlNone
    Selection.Borders(xlDiagonalUp).LineStyle = xlNone
    With Selection.Borders(xlEdgeLeft)
        .LineStyle = xlContinuous
        .Weight = xlThin
        .ColorIndex = xlAutomatic
    End With
    With Selection.Borders(xlEdgeTop)
        .LineStyle = xlContinuous
        .Weight = xlThin
        .ColorIndex = xlAutomatic
    End With
    With Selection.Borders(xlEdgeBottom)
        .LineStyle = xlContinuous
        .Weight = xlThin
        .ColorIndex = xlAutomatic
    End With
    With Selection.Borders(xlEdgeRight)
        .LineStyle = xlContinuous
        .Weight = xlThin
        .ColorIndex = xlAutomatic
    End With
    With Selection.Borders(xlInsideVertical)
        .LineStyle = xlContinuous
        .Weight = xlThin
        .ColorIndex = xlAutomatic
    End With
    With Selection.Borders(xlInsideHorizontal)
        .LineStyle = xlContinuous
        .Weight = xlThin
        .ColorIndex = xlAutomatic
    End With
  end if
next celle

end sub

Thank you so much:-)
beacska

Welcome to the forum.

What line generates the error?

Gotta go. Try this:

Sub FormatTable()
    Dim cell    As Range

    For Each cell In Sheets("Sheet1").Range("A2", Sheets("Sheet1").Cells(Rows.Count, "A").End(xlUp))
        If IsEmpty(cell.Value) And _
           IsEmpty(cell.Offset(1, 0).Value) And _
           IsEmpty(cell.Offset(2, 0).Value) And _
           IsEmpty(cell.Offset(3, 0).Value) Then
            Range("A1:H2").Copy Destination:=cell.Offset(1)
            cell.Offset(-1, 0).Font.Bold = True
            With cell.Offset(5, 0).CurrentRegion.Borders
                .LineStyle = xlContinuous
                .Weight = xlThin
                .ColorIndex = xlAutomatic
            End With
        End If
    Next cell
End Sub

This is working perfect. :-) Thank you soo much sgh

But there is just one problem, I need to cutomise this for every different set of tables. For the one I'm working on now it should find 7 blank cells and also the rage to copy is different. I did it in this way, but now it gives me this error: "Subscript out of range"

Sub FormatTable()
    Dim cell    As Range

    For Each cell In Sheets("Sheet1").Range("A2", Sheets("Sheet1").Cells(Rows.Count, "A").End(xlUp))
        If IsEmpty(cell.Value) And _
           IsEmpty(cell.Offset(1, 0).Value) And _
           IsEmpty(cell.Offset(2, 0).Value) And _
           IsEmpty(cell.Offset(3, 0).Value) And _
           IsEmpty(cell.Offset(4, 0).Value) And _
           IsEmpty(cell.Offset(5, 0).Value) And _
           IsEmpty(cell.Offset(6, 0).Value) Then
            Range("A1:Z3").Copy Destination:=cell.Offset(1)
            cell.Offset(-1, 0).Font.Bold = True
            With cell.Offset(8, 0).CurrentRegion.Borders
                .LineStyle = xlContinuous
                .Weight = xlThin
                .ColorIndex = xlAutomatic
            End With
        End If
    Next cell
End Sub

What can be the problem?
Thanks a lot

I've edited your post to add Code Tags. Please read the Forum Rules before posting again.

What have you done to debug?

What line in the code gives the error, when processing what cell?

You're welcome. My compliments on taking the initiative to modify the code yourself.