GetOpenFilename Properties

[dsexpress]

Hi All,
Is it possible to disable The "Look In:" field of the GetOpenFilename dialogue?
What I would like to do is to keep users from selecting folders other than the CurrentDirectory settings and if possible to keep the user from deleting,copying and pasteing to the files in the current dirrectory displayed.

The code I have is:

Dim objShell As Object
 Dim fileToOpen As Variant
 Dim CurSht As String
   
   Set objShell = CreateObject("WScript.Shell")
     With objShell
      .CurrentDirectory = "f:\masters"
     End With

   fileToOpen = Application.GetOpenFilename("Sheets (*.xls),*.xls", 1, "aai Add Sheets")
      If fileToOpen <> False Then
        CurSht = ActiveSheet.Name
        Sheets.Add Type:=fileToOpen
        ActiveSheet.Move after:=Worksheets(CurSht)
      End If

[shg]

Maybe like this:

Sub x()
    Const sDir As String = "f:\masters"
    
    Dim sFile As String
    Dim sPath

    ChDrive sDir
    ChDir sDir

    sFile = Application.GetOpenFilename("Sheets (*.xls),*.xls", 1, "aai Add Sheets")
    If sFile = "False" Then Exit Sub
    
    If Mid(sFile, InStrRev(sFile, ".") + 1) <> "xls" Then
        MsgBox "Excel files only."
        Exit Sub
    End If
    
    sPath = Left(sFile, InStrRev(sFile, "\") - 1)
    If sPath <> sDir Then
        MsgBox "Files in " & sDir & " only."
        Exit Sub
    End If
        
    Sheets.Add Type:=sFile, After:=ActiveSheet
End Sub

[Leith Ross]

Hello dsexpress,

You can modify Excel to prevent the users from copying, pasting, and deleting files from the menus. To prevent the user from opening folders, in any directory, would require overriding the Application.GetOpenFileName dialog. The problems here are the dialog is part of the Application Object, Excel, which doesn't have any parameters to enable or disable it, and Excel uses the system API call GetOpenFileNameA to dispaly the dialog. You can't change system API calls.

Sincerely,
Leith Ross

[shg]

Right.

My suggestion doesn't keep users from navigating to other folders, it just keeps them from opening files in other than the specified folder.

[dsexpress]

Thanks ,
That helps