Copy data from single sheet to multiple sheets

I almost have it figured out but getting an error on following section of code. I've tried adjusting the code without the quotes, combination of quotes, etc., but nothing seems to work.

Sub Allocate2()

Dim FirstRow As Long
Dim LastRow As Long
Dim i As Integer

FirstRow = 2
LastRow = 5

Sheets("RawData").Select

    For i = 2 To Sheets.Count
        Rows("FirstRow:LastRow").Copy

        With Sheets(i)
            .Range("A2").Paste
        End With
        
        FirstRow = FirstRow + 4
        LastRow = LastRow + 4
    Next i

End Sub

This part of the code works fine if I use

Rows("2:5").Copy

I just can't get it to work when using the variable names.

Any help is appreciated. Thanks.

Hello maacmaac,

There are two ways to accomplish this. Use strings are you have in your code, or use the Range method. I show you both...

Sub Allocate2()

Dim FirstRow As Variant
Dim LastRow As Variant
Dim i As Integer

FirstRow = 2
LastRow = 5

Sheets("RawData").Select

    For i = 2 To Sheets.Count
       'String method
        Rows(FirstRow & ":" & LastRow).Copy

       'Range Method
        'Range(Rows(FirstRow), Rows(LastRow)).Copy

        With Sheets(i)
            .Range("A2").Paste
        End With
        
        FirstRow = FirstRow + 4
        LastRow = LastRow + 4
    Next i

End Sub

Sincerely,
Leith Ross

Leith,

Thanks for the comments. I ran into one more issue which is the next part of the code. The code I want to use is as follows but doesn't work.

    For i = 2 To Sheets.Count
        Rows(FirstRow & ":" & LastRow).Copy

        With Sheets(i)
            .Range("A2").Paste
        End With
        
        FirstRow = FirstRow + 4
        LastRow = LastRow + 4
    Next i

The code will work if the code is like this

    For i = 2 To Sheets.Count
        Rows(FirstRow & ":" & LastRow).Copy

        Sheets(i).Select
        Range("A2").Select
        ActiveSheet.Paste
        Sheets("RawData").Select
        
        FirstRow = FirstRow + 61
        LastRow = LastRow + 61
    Next i

Thanks

P.S. is the first example the more effiecient way write the code?

Hello maacmaac,

Sorry, I was in a hurry and mistyped that line. Change it to this...

     For i = 2 To Sheets.Count
        Rows(FirstRow & ":" & LastRow).Copy
           Sheets(i).Range("A2").PasteSpecial Paste:=xlPasteAll
        FirstRow = FirstRow + 4
        LastRow = LastRow + 4
    Next i

Sincerely,
Leith Ross

Working perfect. Thanks.