Function argument's cell adress

What is CallProb meant to reflect ? You are not passing a Variable of that name - so presumably Percentage ?

As a general rule of thumb when using UDFs - whenever the values being passed originate from cells pass the variables as Ranges and not as values/data types as this gives you far greater flexibility in the long-run, eg instead of:

C1: =FEX(A1,B1)

Function FEX(x As Double, y As Double) As Double
FEX = x * y * x.Offset(,-1).Value
End Function

which would fail (Offset as per your own function) you would use

Function FEX(x As Range, y As Range) As Double
FEX = x.Value * y.Value * x.Offset(,-1).Value
End Function

ie Range objects give you far more flexibility ...

Going back to your actual question... so this is a recursive calc ?

ie Previous should really be a cumulative total, ie

For i = 1 to RollingTime
    Previous = Previous + calc for i
Next i

Correct ?

Based on your original post and:

Originally Posted by John99

RollingTime(2)*Percentage(2)+RollingTime (1)*(1-Percentage(1))*Percentage(2)+RollingTime(0)*(1-Percentage(0)*(1-Percentage(1))*Percentage(2)

Which is 109732508*0,3 + 1017508995*(1-0,2)*0,3+1587172158*(1-0,1)*(1-0,2)*0,3

I wonder if the below will work for you ?

Function TOTALCALLS(rngRT As Range, rngAmt As Range, rngPct As Range) As Variant
Dim bRT As Byte, dblPct As Double
If Application.Count(rngRT, rngAmt, rngPct) < 3 Then
    TOTALCALLS = "Input Error"
    Exit Function
End If
For bRT = 0 To rngRT Step 1
    dblPct = IIf(bRT, dblPct * (1 - rngPct.Offset(, -bRT).Value), rngPct.Value)
    TOTALCALLS = TOTALCALLS + (rngAmt.Offset(, -bRT).Value * dblPct)
Next bRT
End Function

Called from cell as:

B9: =TOTALCALLS(B6,B7,B8)
copied across

For Rolling Time of 2 (ie D9) the above would generate 619951097.3 which I believe ties out to your initial post.

Originally Posted by John99

This might be a stupid question but if I am changing the Percentage for the RollingTime = 2, where can i define that it recalcutes the TOTALCALLS values for RollingTimes =3,4,5..? Now i have to copy across the cells every time I am changing the Percentage argument.

Not at all, this is a key point when using UDFs, you want to avoid the requirement of Application.Volatile given UDFs are generally slower than native Functions, making UDFs Volatile is generally bad news.

The answer is to perhaps alter the approach such that you pass the "cumulative ranges" so to speak, eg:

Function TOTALCALLS(rngRT As Range, rngAmt As Range, rngPct As Range) As Variant
Dim lngRT As Long, dblPct As Double
If Application.Count(rngRT, rngAmt, rngPct) <> Union(rngRT, rngAmt, rngPct).Cells.Count Then
    TOTALCALLS = "Input Error"
    Exit Function
End If
For lngRT = rngRT To 0 Step -1
    dblPct = IIf(lngRT <> rngRT.Value, dblPct * (1 - rngPct(1 + lngRT).Value), rngPct(1 + lngRT).Value)
    TOTALCALLS = TOTALCALLS + (rngAmt(1 + lngRT).Value * dblPct)
Next lngRT
End Function

Using your original file:

B9: =TOTALCALLS(B$6,$B$7:B$7,$B$8:B$8)
copied across

As you alter the % you should find your results adjust accordingly given you're now explicitly setting a dependency in the Function to those % cells, ie altering the % in say D8 would cause all functions from D onwards to recalculate given explicitly referencing D8 in the Function call.

By my reckoning the existing function will work equally well in either direction, all that needs to alter are the range references when calling from the cell

Horizontal:
C7: =TOTALCALLS(C$4,$C$6:C$6,$C$5:C$5)
copied across to P=7

Vertical
E12: =TOTALCALLS($B12,$D$12:$D12,$C$12:$C12)
copied down to E25