passing variable from userform

I am using the following code to open a userform. Once the userform is open, the user has the option to choose a continue button or a cancel button. If the user is choosing continue, the code is not working (it always skips to the "else" portion of my "if" statement. I can't figure out why it is doing this. Thanks. I have attached a sample of workbook, if needed.

Sub UpdateMasterFile()

Dim Continue As String

    Load DisclaimerForm
    DisclaimerForm.Show
    
    If Continue = "Yes" Then
        'do some updates
        MsgBox "Update Complete!  ", vbInformation
    Else
        MsgBox "Update Canceled!  ", vbInformation
    End If

End Sub

Userform code:

Private Sub CheckBox1_Click()

    If CheckBox1.Value = True Then
        ContinueButton.Enabled = True
    Else
        ContinueButton.Enabled = False
    End If
    
End Sub

Private Sub ContinueButton_Click()
    Unload DisclaimerForm
    Continue = "Yes"
End Sub

Private Sub CancelButton_Click()
    Unload DisclaimerForm
    Continue = "No"
End Sub

Hi maacmaac
all you needed to do was call the sub

try....

Private Sub ContinueButton_Click()
Unload.DisclaimerForm
Continue = "Yes"
UpdateMasterFile
End Sub

Private Sub CancelButton_Click()
    Unload DisclaimerForm
    Continue = "No"
   UpdateMasterFile
End Sub

Sub UpdateMasterFile()

   If Continue = "Yes" Then
        'do some updates
        MsgBox "Update Complete!  ", vbInformation
    Else
        MsgBox "Update Canceled!  ", vbInformation
    End If

End Sub

You could change the userform's code to this. (Note the added function.)

Private Sub CheckBox1_Click()
    If CheckBox1.Value = True Then
        ContinueButton.Enabled = True
    Else
        ContinueButton.Enabled = False
    End If
End Sub

Private Sub ContinueButton_Click()
    Me.Hide
End Sub

Private Sub CancelButton_Click()
    Unload Me
End Sub

Public Function ContinueUpdate() As Boolean
    Me.Show
    ContinueUpdate = DisclaimerForm.CheckBox1.Value
    Unload DisclaimerForm
End Function

and change the calling routine to

Sub UpdateMasterFile()
    If DisclaimerForm.ContinueUpdate Then
        'do some updates
        MsgBox "Update Complete!  ", vbInformation
    Else
        MsgBox "Update Canceled!  ", vbInformation
    End If
End Sub

The technique is like returning the value of a function in a custom Class.
Note: In the Function ContinueUpdate, all references after the Me.Show line should be to DisclaimerForm rather than Me, in case the user Cancels or corner X's.

Pike's solution will solve your problem.

The reason it does not work is due to the scope of your variables.
The variable Continue declared in the UpdateMasterFile routine is not the same variable used in the button click events.

http://www.ozgrid.com/VBA/variable-scope-lifetime.htm