moving 'semi'--duplicates up and alongside

Attached is a sample file. Column A is an identifer for a specific property. Column B represents improvements to the property. You will notice that column A can repeat, but column B is unique to the Column A. What I hope to do is if Column A repeats itself, move the improvement into a new column, in the same row as the repeating value in Column A. Sheet 2 is a hand-prepared sheet of the desired result. The result will be Column A filled with unique values and Columns B, C, ...holding what was previously in Column B for repeating values of Column A. Hopefully, the example will be a clearer picture of what I am trying to do.

I have been working on a Macro (as it works well with the other things I am doing) but I am dealing with some faulty scripting (mine!)

Thank you in advance and any advice you can offer is appreciated!

Try this:

Option Explicit

Sub x()
    Dim wks         As Worksheet
    Dim r           As Range
    Dim iRow        As Long
    Dim iOfs        As Long

    Set wks = Worksheets("Sheet1")
    With wks
        .UsedRange.Sort Key1:=.UsedRange(1), Order1:=xlAscending
        Set r = .Range("A1", .Cells(.Rows.Count, "A").End(xlUp))
        iRow = 2
        
        Do While iRow <= r.Rows.Count + r.Row - 1
            iOfs = 1
            With r(iRow, 1)
                Do While .Offset(iOfs).Value = .Value
                    .Offset(iOfs, 1).Copy Destination:=.Offset(, iOfs + 1)
                    .Offset(iOfs).Resize(, 2).ClearContents
                    iOfs = iOfs + 1
                Loop
            End With
            iRow = iRow + iOfs
        Loop
        .UsedRange.Sort Key1:=.UsedRange(1), Order1:=xlAscending
    End With
End Sub